Kako izbrisati vrstice glede na barvo ozadja v Excelu?

Kako lahko izbrišete celotne vrstice glede na barvo ozadja? V tem primeru moram izbrisati vse vrstice, katere celice so napolnjene z modro barvo ozadja, kot je prikazano na sliki spodaj. V tem članku boste dobili nekaj kod za dosego te naloge v Excelu.

Izbrišite vrstice z določeno barvo ozadja glede na vsako celico

Izbrišite vrstice z določeno barvo ozadja glede na en stolpec

Izbrišite vrstice z določeno barvo ozadja glede na vsako celico

Če imate nabor podatkov, ki so naključno napolnjeni z nekaterimi barvami celic, in morate izbrisati vrstice, katerih barva celice je modra, kot je prikazano na sliki spodaj:

Če želite izbrisati to vrsto vrstic, lahko uporabite naslednjo kodo VBA, naredite tako:

1. Držite tipko ALT + F11 tipke za odpiranje Microsoft Visual Basic za aplikacije okno.

2. Kliknite Vstavi > Moduliin prilepite naslednjo kodo v Moduli Okno.

Koda VBA: Izbrišite vrstice, katere celice vsebujejo določeno barvo polnila:

Sub DeleteRows()
'Updateby Extendoffice
    Dim rngCl As Range
    Dim xRows As Long
    Dim xCol As Long
    Dim colorLg As Long
    On Error Resume Next
    Set rngCl = Application.InputBox _
        (Prompt:="Select a cell with the background color to be deleted", _
        Title:="Kutools for Excel", Type:=8)
    On Error GoTo 0
    If rngCl Is Nothing Then
        MsgBox "User cancelled operation." & vbCrLf & _
        "Processing terminated", vbInformation, "Kutools for Excel"
        Exit Sub
    End If
    colorLg = rngCl.Interior.Color
    Application.ScreenUpdating = False
    With ActiveSheet.UsedRange
        For xRows = .Rows.Count To 1 Step -1
            For xCol = 1 To .Columns.Count
                           If .Cells(xRows, xCol).Interior.Color = colorLg Then
                    .Rows(xRows).Delete
                    Exit For
                End If
            Next xCol
        Next xRows
    End With
    Application.ScreenUpdating = True
End Sub

3. In nato pritisnite F5 tipko za zagon te kode in pojavilo se bo pozivno polje, ki vas bo opozorilo na izbiro celice z barvo polnila, ki jo želite izbrisati, glejte sliko zaslona:

4. Nato kliknite OK, in vse vrstice so bile izbrisane, če je celica z določeno barvo polnila.

Izbrišite vrstice z določeno barvo ozadja glede na en stolpec

Če želite izbrisati vrstice z določeno barvo, ki temelji na samo enem stolpcu, na primer izbrišite vrstice z modro barvo v stolpcu A in dobite spodnji posnetek zaslona, ​​tukaj je tudi koda VBA vam lahko naklonjena.

1. Držite tipko ALT + F11 tipke za odpiranje Microsoft Visual Basic za aplikacije okno.

2. Kliknite Vstavi > Moduliin prilepite naslednjo kodo v Moduli Okno.

Koda VBA: Izbrišite vrstice na podlagi stolpca, katerega celice imajo določeno barvo polnila:

Sub deleterow()
'UpdateBY Extendoffice
   Dim xRg As Range, rgDel As Range
    For Each xRg In ThisWorkbook.ActiveSheet.Range("A2:A21")
        If xRg.Interior.ColorIndex = 20 Then
            If rgDel Is Nothing Then
                Set rgDel = xRg
            Else
                Set rgDel = Union(rgDel, xRg)
            End If
        End If
    Next xRg
    If Not rgDel Is Nothing Then rgDel.EntireRow.Delete
End Sub

Opombe: V zgornji kodi, A2: A21 je stolpec, ki vsebuje določeno barvo polnila, na podlagi katere želite izbrisati vrstice, število 20 in Barvni indeks = 20 skript je barvni indeks, na podlagi katerega želite izbrisati vrstice. Lahko jih spremenite po svojih potrebah.

3. Nato pritisnite F5 za zagon te kode in vse vrstice, katerih celice vsebujejo modro barvo v stolpcu A, so bile hkrati izbrisane.