Kako izvleči sklic na celico iz formul v Excelu?

Recimo, da imate nekaj dolgih formul in zdaj želite iz formul izvleči vse sklice na celice, kot je prikazano na sliki spodaj. Kako lahko čim hitreje izvlečete sklice na celice iz formul?

Izvlecite sklice na celice iz formul z uporabniško določeno funkcijo

---

Izvlecite sklice na celice iz formul z uporabniško določeno funkcijo

Če želite iz formul izvleči sklice na celice, vam lahko spodnja koda VBA naredi uslugo. Naredite naslednje:

1. Držite tipko ALT + F11 tipke za odpiranje Microsoft Visual Basic za aplikacije okno.

2. Kliknite Vstavi > Moduliin prilepite naslednjo kodo v Moduli Okno.

Koda VBA: Izvleci sklice na celice iz formul:

Function ExtractCellRefs(Rg As Range) As String
'Updateby Extendoffice
    Dim xRetList As Object
    Dim xRegEx As Object
    Dim I As Long
    Dim xRet As String
    Application.Volatile
    Set xRegEx = CreateObject("VBSCRIPT.REGEXP")
    With xRegEx
        .Pattern = "('?[a-zA-Z0-9\s\[\]\.]{1,99})?'?!?\$?[A-Z]{1,3}\$?[0-9]{1,7}(:\$?[A-Z]{1,3}\$?[0-9]{1,7})?"
        .Global = True
        .MultiLine = True
        .IgnoreCase = False
    End With
    Set xRetList = xRegEx.Execute(Rg.Formula)
    If xRetList.Count > 0 Then
        For I = 0 To xRetList.Count - 1
            xRet = xRet & xRetList.Item(I) & ", "
        Next
        ExtractCellRefs = Left(xRet, Len(xRet) - 2)
    Else
        ExtractCellRefs = "No Matches"
    End If
End Function

3. Po lepljenju kode shranite kodo in se vrnite na delovni list ter vnesite to formulo: = izvleček celic (G2) (G2 je celica, ki vsebuje formulo, v katero želite izvleči sklice na celico) v celico, kjer želite dobiti rezultat, in pritisnite Vnesite ključ, vsi sklici na celice so bili izvlečeni iz formule, glej posnetek zaslona: