Preskoči na glavno vsebino

Excel INDEX MATCH: Osnovna in napredna iskanja

V Excelu je natančno pridobivanje določenih podatkov pogosto nujno. Čeprav imata funkciji INDEX in MATCH vsaka svoje prednosti, njuna kombinacija odklene zmogljiv nabor orodij za iskanje podatkov. Skupaj omogočata vrsto zmožnosti iskanja, od osnovnih vodoravnih in navpičnih iskanj do naprednejših funkcij, kot so dvosmerno iskanje, ki razlikuje med velikimi in malimi črkami, ter iskanje po več kriterijih. Ponuja izboljšane zmogljivosti v primerjavi z VLOOKUP, združevanje INDEX in MATCH omogoča širši nabor možnosti iskanja podatkov. V tej vadnici se poglobimo v globino možnosti, ki jih lahko dosežejo skupaj.


Kako uporabljati INDEX in MATCH v Excelu

Preden uporabimo funkciji INDEX in MATCH, se prepričajmo, da vemo, kako nam lahko INDEX in MATCH najprej pomagata pri iskanju vrednosti.


Kako uporabljati funkcijo INDEX v Excelu

O INDEX funkcija v Excelu vrne vrednost na danem mestu v določenem obsegu. Sintaksa funkcije INDEX je naslednja:

=INDEX(array, row_num, [column_num])
  • matrika (obvezno) se nanaša na obseg, iz katerega želite vrniti vrednost.
  • vrstica_num (obvezno, razen če stolpec_številka je prisoten) se nanaša na številko vrstice matrike.
  • stolpec_številka (izbirno, vendar obvezno, če vrstica_num je izpuščeno) se nanaša na številko stolpca matrike.

Na primer vedeti ocena Jeffaje 6študent na seznamu, lahko uporabite funkcijo INDEX takole:

=INDEX(C2:C11,6)

ujemanje indeksa Excel 01

√ Opomba: obseg C2: C11 kjer so navedeni rezultati, medtem ko je številka 6 najde izpitno oceno 6th študent.

Tukaj naredimo majhen test. Za formulo =KAZALO(A1:C1,2;XNUMX), kakšno vrednost bo vrnil? --- Da, vrnilo se bo Datum rojstvaje 2nd vrednost v dani vrstici.

Zdaj bi morali vedeti, da lahko funkcija INDEX odlično deluje z vodoravnimi ali navpičnimi razponi. Kaj pa, če ga potrebujemo, da vrne vrednost v večjem obsegu z več vrsticami in stolpci? No, v tem primeru bi morali uporabiti tako številko vrstice kot številko stolpca. Na primer, da bi izvedeli Jeffov rezultat znotraj obsega tabele namesto enega samega stolpca lahko njegov rezultat poiščemo z a številka vrstice 6 in številka stolpca 3 v celic od A2 do C11 Všečkaj to:

=INDEX(A2:C11,6,3)

ujemanje indeksa Excel 02

Stvari, ki jih moramo vedeti o funkciji INDEX v Excelu:
  • Funkcija INDEX lahko deluje z navpičnimi in vodoravnimi razponi.
  • Če oboje vrstica_num in stolpec_številka uporabljajo se argumenti, vrstica_num gre pred stolpec_številka, INDEX pa pridobi vrednost na presečišču podanega vrstica_num in stolpec_številka.

Vendar pa za res veliko bazo podatkov z več vrsticami in stolpci zagotovo ni priročno, da uporabimo formulo z natančno številko vrstice in številko stolpca. In to je to, ko bi morali kombinirati uporabo funkcije MATCH.


Kako uporabljati funkcijo MATCH v Excelu

Funkcija MATCH v Excelu vrne številsko vrednost, lokacijo določenega elementa v danem obsegu. Sintaksa funkcije MATCH je naslednja:

=MATCH(lookup_value, lookup_array, [match_type])
  • lookup_value (obvezno) se nanaša na vrednost za ujemanje v iskalni_array.
  • iskalni_array (obvezno) se nanaša na obseg celic, kjer želite, da MATCH išče.
  • match_type (neobvezno): 1, 0 or -1.
    • 1 (privzeto) bo MATCH našel največjo vrednost, ki je manjša ali enaka lookup_value. Vrednosti v iskalni_array mora biti postavljen v naraščajočem vrstnem redu.
    • 0, MATCH bo našel prvo vrednost, ki je natančno enaka lookup_value. Vrednosti v iskalni_array lahko v poljubnem vrstnem redu. (V primerih, ko je vrsta ujemanja nastavljena na 0, lahko uporabite nadomestne znake.)
    • -1, MATCH bo našel najmanjšo vrednost, ki je večja ali enaka lookup_value. Vrednosti v iskalni_array morajo biti postavljene v padajočem vrstnem redu.

Na primer vedeti mesto Vere na seznamu imen, lahko uporabite formulo MATCH takole:

=MATCH("Vera",A2:A11,0)

ujemanje indeksa Excel 3

√ Opomba: rezultat "4" pomeni, da je ime "Vera" na 4. mestu seznama.

Stvari, ki jih moramo vedeti o funkciji MATCH v Excelu:
  • Funkcija MATCH vrne položaj iskane vrednosti v iskalnem nizu, ne same vrednosti.
  • Funkcija MATCH vrne prvo ujemanje v primeru dvojnikov.
  • Tako kot funkcija INDEX lahko tudi funkcija MATCH deluje z navpičnimi in vodoravnimi razponi.
  • MATCH ne razlikuje med velikimi in malimi črkami.
  • Če lookup_value formule MATCH je v obliki besedila, v narekovajih.
  • Če lookup_value ni najti v iskalni_arrayje # N / A napaka je vrnjena.

Zdaj, ko vemo o osnovnih rabah funkcij INDEX in MATCH v Excelu, zavihajmo rokave in se pripravimo združiti obe funkciji.


Kako združiti INDEX in MATCH v Excelu

Oglejte si spodnji primer, da ugotovite, kako lahko združimo funkcije INDEX in MATCH:

Najti Evelyn rezultat, ob zavedanju, da so ocene izpita v 3rd stolpec, lahko uporabite funkcijo MATCH, da samodejno določite položaj vrstice brez potrebe po ročnem štetju. Nato lahko uporabimo funkcijo INDEX za pridobitev vrednost na presečišču identificirane vrstice in 3. stolpca:

=INDEX(A2:C11,MATCH("Evelyn",A2:A11,0),3)

ujemanje indeksa Excel 4

No, ker je formula morda videti nekoliko zapletena, pojdimo skozi vsak njen del.

ujemanje indeksa Excel 5

O INDEX formula vsebuje tri argumente:

  • vrstica_num: MATCH("Evelyn";A2:A11,0;XNUMX) zagotavlja INDEX s položajem vrstice vrednosti "Evelyn" v območju A2: A11, Ki je 5.
  • stolpec_številka: 3 določa 3rd stolpec za INDEX, da poiščete rezultat v matriki.
  • matrika: A2: C11 ukaže INDEXu, naj vrne ujemajočo se vrednost na presečišču navedene vrstice in stolpca znotraj obsega od A2 do C11. Končno dobimo rezultat 90.

V zgornji formuli smo uporabili trdo kodirano vrednost, "Evelyn". Vendar so v praksi trdo kodirane vrednosti nepraktične, saj bi jih bilo treba spremeniti vsakič, ko želimo iskati različne podatke, kot je rezultat drugega študenta. V takšnih scenarijih lahko uporabimo reference celic za ustvarjanje dinamičnih formul. Na primer, v tem primeru bom spremenite "Evelyn" v F2:

=INDEX(A2:C11,MATCH(F2,A2:A11,0),3)

(AD) Poenostavite iskanje s Kutools: vnašanje formule ni potrebno!

Kutools za Excel's Super iskanje zagotavlja različna orodja za iskanje prilagojeno za vsako vašo potrebo. Ne glede na to, ali izvajate iskanje po več kriterijih, iščete po več listih ali izvajate iskanje ena proti mnogo, Super iskanje poenostavi postopek z le nekaj kliki. Raziščite te funkcije da vidimo kako Super iskanje spremeni vaš način interakcije z Excelovimi podatki. Poslovite se od težav s pomnjenjem zapletenih formul.

Orodja za iskanje Kutools

Kutools za Excel - Omogoča vam več kot 300 priročnih funkcij za produktivnost brez truda. Ne zamudite priložnosti, da ga preizkusite s 30-dnevnim brezplačnim preizkusom vseh funkcij! Začnite zdaj!


Primeri formul INDEX in MATCH

V tem delu bomo govorili o različnih okoliščinah za uporabo funkcij INDEX in MATCH za izpolnjevanje različnih potreb.


INDEX in MATCH, da uporabite dvosmerno iskanje

V prejšnjem primeru smo poznali številko stolpca in uporabili formulo MATCH, da bi našli številko vrstice. Kaj pa, če nismo prepričani tudi glede številke stolpca?

V takih primerih lahko izvedemo dvosmerno iskanje, znano tudi kot iskanje matrike, z uporabo dveh funkcij MATCH: ena za iskanje številke vrstice in druga za določitev številke stolpca. Na primer vedeti Evelyn rezultat, moramo uporabiti formulo:

=INDEX(A2:C11,MATCH("Evelyn",A2:A11,0),MATCH("Score",A1:C1,0))

ujemanje indeksa Excel 6

Kako deluje ta formula:
  • Prva formula MATCH najde Evelynino lokacijo na seznamu A2:A11 in zagotavlja 5 kot številko vrstice za INDEX.
  • Druga formula MATCH določa stolpec za rezultate in donose 3 kot številko stolpca za INDEX.
  • Formula je poenostavljena na =KAZALO(A2:C11,5,3;XNUMX), in INDEX vrne 90.

INDEX in MATCH, da uporabite levo iskanje

Zdaj pa razmislimo o scenariju, kjer morate določiti Evelyn razred. Morda ste opazili, da je stolpec razreda postavljen levo od stolpca imena, kar presega zmožnosti druge zmogljive Excelove funkcije iskanja, VLOOKUP.

Pravzaprav je zmožnost izvajanja iskanja na levi strani eden od vidikov, kjer kombinacija INDEX in MATCH zasenči VLOOKUP.

Najti Evelyn razred, uporabite naslednjo formulo za poiščite Evelyn v B2:B11 in pridobi ustrezno vrednost iz A2:A11.

=INDEX(A2:A11,MATCH("Evelyn",B2:B11,0))

ujemanje indeksa Excel 7

Opomba: Preprosto lahko izvedete levo iskanje za določene vrednosti z uporabo POGLED od desne proti levi značilnost Kutools za Excel z le nekaj kliki. Če želite implementirati funkcijo, se pomaknite do Kutools v Excelu in kliknite Super iskanje > POGLED od desne proti levi v Formula skupina.

POGLED od desne proti levi

Če še niste namestili Kutools, kliknite tukaj za prenesite in pridobite 30-dnevno brezplačno preskusno različico vseh funkcij!


INDEX in MATCH, da uporabite iskanje, ki razlikuje velike in male črke

Funkcije MATCH same po sebi ne razlikujejo med velikimi in malimi črkami. Ko pa zahtevate, da vaša formula razlikuje med velikimi in malimi črkami, jo lahko izboljšate tako, da vključite Točno funkcijo. Če združite funkcijo MATCH in EXACT v formuli INDEX, lahko nato učinkovito izvedete iskanje, ki razlikuje med velikimi in malimi črkami, kot je prikazano spodaj:

=INDEX(array, MATCH(TRUE, EXACT(lookup_value, lookup_array), 0))
  • matrika se nanaša na obseg, iz katerega želite vrniti vrednost.
  • lookup_value se nanaša na vrednost, ki se ujema z velikimi in malimi črkami v iskalni_array.
  • iskalni_array se nanaša na obseg celic, s katerimi želite primerjati MATCH lookup_value.

Na primer vedeti JIMMY-jev rezultat na izpitu, uporabite naslednjo formulo:

=INDEX(C2:C11,MATCH(TRUE,EXACT("JIMMY",A2:A11),0))

√ Opomba: To je matrična formula, ki zahteva, da vnesete Ctrl + Shift + Vnesite, razen v Excelu 365 in Excelu 2021.

ujemanje indeksa Excel 8

Kako deluje ta formula:
  • Funkcija EXACT primerja "JIMMY" z vrednostmi na seznamu A2: A11, ob upoštevanju velikih in malih črk: Če se niza natančno ujemata, upoštevajoč tako velike kot male črke, vrne EXACT TRUE; sicer se vrne FALSE. Kot rezultat dobimo matriko, ki vsebuje vrednosti TRUE in FALSE.
  • Funkcija MATCH nato pridobi položaj prve vrednosti TRUE v nizu, ki bi moral biti 10.
  • Končno INDEX pridobi vrednost na 10mesto, ki ga zagotavlja MATCH v matriki.

Opombe:

  • Ne pozabite pravilno vnesti formule s pritiskom na Ctrl + Shift + Enter, razen če uporabljate Excel 365 or Excel 2021, v tem primeru preprosto pritisnite Vnesite.
  • Zgornja formula išče znotraj enega seznama C2: C11. Če želite iskati znotraj obsega z več stolpci in vrsticami, recimo A2: C11, morate INDEX-u ponuditi številke stolpcev in vrstic:
  • =INDEX(A2:C11,MATCH(TRUE,EXACT("JIMMY",A2:A11),0),3)
  • V tej revidirani formuli uporabljamo funkcijo MATCH za iskanje "JIMMY" ob upoštevanju velikih in malih črk v obsegu A2: A11, in ko najdemo ujemanje, pridobimo ustrezno vrednost iz 3rd stolpec obsega A2: C11.

INDEX in MATCH, da poiščete najbližje ujemanje

V Excelu lahko naletite na situacije, ko morate najti najbližje ali najbližje ujemanje z določeno vrednostjo znotraj nabora podatkov. V takšnih scenarijih je uporaba kombinacije funkcij INDEX in MATCH, skupaj s funkcijama ABS in MIN, lahko izjemno koristna.

=INDEX(array, MATCH(MIN(ABS(lookup_array - lookup_value)), ABS(lookup_array - lookup_value),0))
  • matrika se nanaša na obseg, iz katerega želite vrniti vrednost.
  • iskalni_array se nanaša na obseg vrednosti, kjer želite najti najbližje ujemanje lookup_value.
  • lookup_value se nanaša na vrednost, da najde njeno najbližje ujemanje.

Na primer, če želite izvedeti katerega rezultat je najbližji 85, uporabite naslednjo formulo za poiščite rezultat, ki je najbližji 85 v C2:C11 in pridobi ustrezno vrednost iz A2:A11.

=INDEX(A2:A11,MATCH(MIN(ABS(C2:C11-85)),ABS(C2:C11-85),0))

√ Opomba: To je matrična formula, ki zahteva, da vnesete Ctrl + Shift + Vnesite, razen v Excelu 365 in Excelu 2021.

Kako deluje ta formula:
  • ABS (C2:C11-85) izračuna absolutno razliko med vsako vrednostjo v območju C2: C11 in 85, kar ima za posledico niz absolutnih razlik.
  • MIN(ABS(C2:C11-85)) poišče najmanjšo vrednost v nizu absolutnih razlik, ki predstavlja razliko, ki je najbližja 85.
  • Funkcija MATCH MATCH(MIN(ABS(C2:C11-85)),ABS(C2:C11-85),0) nato najde položaj najmanjše absolutne razlike v nizu absolutnih razlik, ki bi moral biti 10.
  • Končno INDEX pridobi vrednost na mestu na seznamu A2: A11 ki ustreza rezultatu, ki je najbližji 85 v območju C2: C11.

Opombe:

  • Ne pozabite pravilno vnesti formule s pritiskom na Ctrl + Shift + Enter, razen če uporabljate Excel 365 or Excel 2021, v tem primeru preprosto pritisnite Vnesite.
  • V primeru neodločenega rezultata bo ta formula vrnila prvo tekmo.
  • Najti najbližje ujemanje s povprečnim rezultatom, zamenjati 85 v formuli s AVERAGE(C2:C11).

INDEX in MATCH za uporabo iskanja z več merili

Če želite najti vrednost, ki izpolnjuje več pogojev, pri čemer morate iskati v dveh ali več stolpcih, uporabite naslednjo formulo. Formula vam omogoča, da izvedete iskanje po več kriterijih, tako da določite različne pogoje v različnih stolpcih, kar vam pomaga najti želeno vrednost, ki ustreza vsem podanim kriterijem.

=INDEX(array, MATCH(1, (lookup_value1=lookup_array1) * (lookup_value2=lookup_array2) * (…), 0))

√ Opomba: To je matrična formula, ki zahteva, da vnesete Ctrl + Shift + Vnesite. V vrstici s formulo se bo nato prikazal par zavitih oklepajev.

  • matrika se nanaša na obseg, iz katerega želite vrniti vrednost.
  • (lookup_value=lookup_array) predstavlja en sam pogoj. Ta pogoj preverja, ali določen lookup_value se ujema z vrednostmi v iskalni_array.

Na primer, da bi našli ocena Coco iz razreda A, katere datum rojstva je 7/2/2008, lahko uporabite naslednjo formulo:

=INDEX(D2:D11,MATCH(1,(G2=A2:A11)*(G3=B2:B11)*(G4=C2:C11),0))

ujemanje indeksa Excel 9

Opombe:

  • V tej formuli se izognemo trdemu kodiranju vrednosti, kar olajša pridobivanje rezultata z različnimi informacijami s spreminjanjem vrednosti v celicah G2, G3in G4.
  • Formulo morate vnesti s pritiskom na Ctrl + Shift + Enter razen v Excel 365 or Excel 2021, kjer preprosto pritisnete Vnesite.
    Če nenehno pozabite uporabiti Ctrl + Shift + Enter če želite dokončati formulo in dobiti napačne rezultate, uporabite naslednjo nekoliko bolj zapleteno formulo, s katero lahko dokončate preprosto Vnesite ključ:
    =INDEX(D2:D11,MATCH(1,INDEX((G2=A2:A11)*(G3=B2:B11)*(G4=C2:C11),0,1),0))
  • Formule so lahko zapletene in si jih je težko zapomniti. Če želite poenostaviti iskanje po več kriterijih brez potrebe po ročnem vnosu formule, razmislite o uporabi Kutools za ExcelJe Iskanje v več pogojih funkcija. Ko namestite Kutools, se pomaknite do Kutools v Excelu in kliknite Super iskanje > Iskanje v več pogojih v Formula skupina.

    Iskanje v več pogojih

    Če še niste namestili Kutools, kliknite tukaj za prenesite in pridobite 30-dnevno brezplačno preskusno različico vseh funkcij!


INDEX in MATCH, da uporabite iskanje v več stolpcih

Predstavljajte si scenarij, kjer imate opravka z več podatkovnimi stolpci. Prvi stolpec deluje kot ključ za razvrščanje podatkov v drugih stolpcih. Če želite določiti kategorijo ali klasifikacijo za določen vnos, boste morali izvesti iskanje po podatkovnih stolpcih in ga povezati z ustreznim ključem v referenčnem stolpcu.

Kako lahko na primer v spodnji tabeli povežemo učenca Shawna z njegovim ustreznim razredom z uporabo INDEX in MATCH? No, to lahko dosežete s formulo, vendar je formula precej obsežna in jo je lahko težko razumeti, kaj šele zapomniti in tipkati.

=IFERROR(INDEX($A$2:$A$4,MATCH(IF(SUM(MMULT(--($B$2:$E$4=G2),TRANSPOSE(COLUMN($B$2:$E$4)^0)))>0,1,-1),MMULT(--($B$2:$E$4=G2),TRANSPOSE(COLUMN($B$2:$E$4)^0))^0,0)), "")

Tu pač Kutools za Excel's Indeks in ujemanje v več stolpcih funkcija pride prav. Poenostavlja postopek, saj omogoča hitro in enostavno povezovanje določenih vnosov z njihovimi ustreznimi kategorijami. Preprosto odklenite to zmogljivo orodje in Shawna preprosto uskladite z njegovim razredom prenesite in namestite dodatek Kutools for Excel, nato pa naredite naslednje:

  1. Izberite ciljno celico, v kateri želite prikazati ujemajoči se razred.
  2. o Kutools jeziček, kliknite Pomočnik za formulo > Iskanje in reference > Indeks in ujemanje v več stolpcih.
  3. ujemanje indeksa Excel 11
  4. V pojavnem pogovornem oknu naredite naslednje:
    1. Kliknite 1 ikona indeksa ujemanja Excel gumb poleg Iskanje_col da izberete stolpec, ki vsebuje ključne informacije, ki jih želite vrniti, tj. imena razredov. (Tu lahko izberete samo en stolpec.)
    2. Kliknite 2 ikona indeksa ujemanja Excel gumb poleg Tabela_rng da izberete celice, ki se ujemajo z vrednostmi v izbranem Iskanje_col, tj. imena učencev.
    3. Kliknite 3 ikona indeksa ujemanja Excel gumb poleg Iskalna_vrednost da izberete celico, ki vsebuje ime učenca, ki ga želite ujemati z njegovim razredom, v tem primeru Shawn.
    4. klik OK.
    5. ujemanje indeksa Excel 12

Rezultat

Kutools je samodejno ustvaril formulo in v ciljni celici boste takoj videli Shawnovo ime razreda.

Opomba: Če želite preizkusiti Indeks in ujemanje v več stolpcih funkcijo, boste potrebovali Kutools za Excel nameščen na vašem računalniku. Če ga še niste namestili, ne čakajte --- Prenesite in namestite ga zdaj za 30-dnevno brezplačno preskusno različico brez omejitev. Poskrbite, da bo Excel danes pametnejši!


INDEX in MATCH za iskanje prve vrednosti, ki ni prazna

Če želite iz stolpca ali vrstice pridobiti prvo vrednost, ki ni prazna, brez upoštevanja napak, lahko uporabite formulo, ki temelji na funkcijah INDEX in MATCH. Če pa ne želite prezreti napak iz svojega obsega, dodajte funkcijo ISBLANK.

  • Pridobite prvo neprazno vrednost v stolpcu ali vrstici in prezrite napake:
  • =INDEX(B4:B15,MATCH(TRUE,INDEX((B4:B15<>0),0),0))
  • Pridobite prvo neprazno vrednost v stolpcu ali vrstici, vključno z napakami:
  • =INDEX(B4:B15,MATCH(FALSE,ISBLANK(B4:B15),0))

Opombe:


INDEX in MATCH za iskanje prve številske vrednosti

Če želite pridobiti prvo številsko vrednost iz stolpca ali vrstice, uporabite formulo, ki temelji na funkcijah INDEX, MATCH in ISNUMBER.

=INDEX(B4:B15,MATCH(TRUE,ISNUMBER(B4:B15),0))

Opombe:


INDEX in MATCH za iskanje MAX ali MIN povezav

Če morate pridobiti vrednost, povezano z največjo ali najmanjšo vrednostjo znotraj obsega, lahko uporabite funkcijo MAX ali MIN skupaj s funkcijama INDEX in MATCH.

  • INDEX in MATCH za pridobitev vrednosti, povezane z največjo vrednostjo:
  • =INDEX(array, MATCH(MAX(lookup_array), lookup_array, 0))
  • INDEX in MATCH za pridobitev vrednosti, povezane z najmanjšo vrednostjo:
  • =INDEX(array, MATCH(MIN(lookup_array), lookup_array, 0))
  • V zgornjih formulah sta dva argumenta:
    • matrika se nanaša na obseg, iz katerega želite vrniti povezane informacije.
    • iskalni_array predstavlja nabor vrednosti, ki jih je treba pregledati ali iskati glede na določena merila, tj. največje ali najmanjše vrednosti.

Na primer, če želite ugotoviti kdo ima najvišjo oceno, uporabite naslednjo formulo:

=INDEX(A2:A11,MATCH(MAX(C2:C11),C2:C11,0))

Kako deluje ta formula:
  • MAX(C2:C11) išče najvišjo vrednost v območju C2: C11, Ki je 96.
  • Funkcija MATCH nato poišče položaj najvišje vrednosti v matriki C2: C11, kar bi moralo biti 1.
  • Končno INDEX pridobi 1st vrednost na seznamu A2: A11.

Opombe:

  • V primeru več kot ene največje ali najmanjše vrednosti, kot je razvidno iz zgornjega primera, kjer sta dva študenta dosegla enako najvišjo oceno, bo ta formula vrnila prvo ujemanje.
  • Če želite ugotoviti, kdo ima najnižjo oceno, uporabite naslednjo formulo:
    =INDEX(A2:A11,MATCH(MIN(C2:C11),C2:C11,0))

Nasvet: Prilagodite svoja sporočila o napakah #N/A

Pri delu z Excelovima funkcijama INDEX in MATCH lahko naletite na napako #N/A, če ni ujemajočega se rezultata. Na primer, v spodnji tabeli se pri poskusu iskanja rezultata učenke z imenom Samantha pojavi napaka #N/A, ker je ni v naboru podatkov.

ujemanje indeksa Excel 15

Če želite, da bodo vaše preglednice uporabniku prijaznejše, lahko to sporočilo o napaki prilagodite tako, da ovijete svojo formulo INDEX MATCH v funkcijo IFNA:

=IFNA(INDEX(C2:C11,MATCH(F2,A2:A11,0)),"Not found")

ujemanje indeksa Excel 16

Opombe:

  • Sporočila o napakah lahko prilagodite tako, da zamenjate "Ni najdeno" s poljubnim besedilom po vaši izbiri.
  • Če želite obravnavati vse napake, ne le #N/A, razmislite o uporabi NAPAKA namesto IFNA:
    =IFERROR(INDEX(C2:C11,MATCH(F2,A2:A11,0)),"Not found")

    Upoštevajte, da morda ni priporočljivo zatreti vseh napak, ker služijo kot opozorila za morebitne težave v vaših formulah.

Zgoraj je vsa ustrezna vsebina, povezana s funkcijama INDEX in MATCH v Excelu. Upam, da vam bo vadnica v pomoč. Če želite raziskati več nasvetov in trikov za Excel, kliknite tukaj za dostop do naše obsežne zbirke več kot tisoč vadnic.

Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations