Preskoči na glavno vsebino

Enostavno preštejte edinstvene in različne vrednosti – 7 primerov

Običajno so v Excelu edinstvene vrednosti vrednosti, ki se na seznamu pojavijo samo enkrat brez kakršnih koli podvajanj, različne vrednosti pa so vse različne vrednosti (edinstvene vrednosti + 1. podvojene pojavitve). Ko delate na velikem naboru podatkov, boste morda morali prešteti število edinstvenih in različnih vrednosti med dvojniki s seznama celic, kot je prikazano na spodnjem posnetku zaslona. Ta vadnica bo predstavila nekaj hitrih trikov za štetje edinstvenih in ločenih vrednosti v Excelu.

Preštejte edinstvene vrednosti v Excelu

Preštejte različne vrednosti (edinstvene in prve podvojene pojavitve) v Excelu


Prenesite vzorčno datoteko

Preštejte edinstvene različne vrednosti


Preštejte edinstvene vrednosti v Excelu

V tem razdelku bomo govorili o nekaterih primerih formul za štetje števila edinstvenih vrednosti, vključno z besedili in številkami na seznamu.

Preštejte edinstvene vrednosti s formulami

Recimo, da imam seznam imen, ki vsebuje nekaj podvojenih imen na seznamu imen. Zdaj moram dobiti samo število edinstvenih imen (ki so zapolnjena z rumeno barvo), kot je prikazano na spodnjem posnetku zaslona:

Za rešitev te težave vam lahko uslugo naredi naslednja matrična formula:

1. korak: Vnosna formula

Vnesite ali kopirajte spodnjo formulo v prazno celico, kjer želite izpisati rezultat:

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
 Opombe: V zgornji formuli, A2: A12 je seznam podatkov, ki jih želite šteti kot edinstvene.

Korak 2: Pritisnite Ctrl + Shift + Enter tipke za pravilen rezultat:

nasveti:

  1. Če vaš seznam celic vsebuje nekatere druge vrste podatkov, kot so števila, logične vrednosti, vrednosti napak itd., bo pri uporabi zgornje formule dobil število edinstvenih vrednosti ne glede na vrsto podatkov.
  2. Če seznam podatkov vsebuje prazne celice, bo ta formula izključila prazne celice.
  3. Da štejejo samo edinstvene besedilne vrednosti če obstajajo druge vrste podatkov, uporabite spodnjo matrično formulo in nato pritisnite Ctrl + Shift + Enter tipke za vrnitev rezultata:
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. Da štejejo samo edinstvena števila s seznama celic, ki vsebuje katero koli vrsto podatkov, uporabite naslednjo matrično formulo in nato pritisnite Ctrl + Shift + Enter tipke za vrnitev rezultata:
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

Kutools za Excel z nekaj kliki preštejte edinstvene vrednosti

Morda bo za vas boleče, če se boste spomnili formul, ko jih boste naslednjič morali uporabiti. Ampak, če imate Kutools za Excel, Z njegovim Preštejte edinstvene vrednosti možnost Pomočnik za formule, lahko dobite rezultat z le nekaj kliki. Oglejte si spodnjo predstavitev:

  1. Kliknite celico, da izpišete rezultat;
  2. Omogočite to funkcijo s klikom Kutools > Pomočnik za formulo > Pomočnik za formulo > Statistični > Preštejte edinstvene vrednosti;
  3. Izberite seznam podatkov > OK.
nasveti:
  1. Če želite uporabiti to funkcijo, bi morali prenesite in namestite najprej.
  2. O Pomočnik za formule funkcija zbira 40+ pogosto uporabljenih formul, kot je npr Izvlecite edinstvene vrednosti, Ekstrahirajte celice z edinstvenimi vrednostmi (vključite prve dvojnike), Preštejte število vrednosti, ločenih z vejico, Vsota na podlagi istega besedila, in več...

Preštejte edinstvene vrednosti v Excelu 365/2021 s formulami

Če uporabljate Excel 365 ali Excel 2021, je na voljo nova funkcija UNIQUE, ki vam lahko pomaga ustvariti enostavnejše formule za štetje edinstvenih vrednosti v nizu podatkov.

Če želite na primer prešteti število edinstvenih imen v obsegu A2:A12, vnesite naslednjo formulo:

1. korak: Kopirajte ali vnesite spodnjo formulo

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
Opombe: V tej formuli, A2: A12 je seznam podatkov, za katerega želite prešteti edinstvene vrednosti.

Korak 2: Pritisnite Vnesite ključ do rezultata:

nasveti:

  1. Če seznam podatkov vsebuje druge vrste podatkov, kot so besedilo, števila, logične vrednosti, vrednosti napak itd., bo ta formula pridobila število edinstvenih vrednosti ne glede na vrsto podatkov.
  2. Zgornja formula bo štela edinstvene vrednosti, vključno s praznimi celicami, če želite izključiti prazne celice, uporabite spodnjo formulo in samo pritisnite Vnesite ključ:
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

Preštejte različne vrednosti (edinstvene in prve podvojene pojavitve) v Excelu

Za štetje različnih vrednosti (edinstvene vrednosti in prve podvojene pojavitve) na seznamu celic bom tukaj predstavil druge formule za doseganje te naloge.

Preštejte različne vrednosti s formulami

V Excelu lahko uporabite katero koli od spodnjih formul, da vrnete število različnih vrednosti.

1. korak: Vnesite katero koli od spodnjih formul

Formula 1: Po vnosu formule pritisnite Vnesite ključ.

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))      

Formula 2: Po vnosu formule pritisnite Ctrl + Shift + Enter ključi.

=SUM(1/COUNTIF(A2:A12,A2:A12))             
Opombe: V teh formulah je A2: A12 je seznam podatkov, za katere želite prešteti različne vrednosti.

Rezultat:

nasveti:

  1. Če seznam podatkov vsebuje druge vrste podatkov, kot so števila, logične vrednosti, vrednosti napak itd., bo ta formula dobila različne vrednosti ne glede na vrsto podatkov.
  2. Pri uporabi zgornje formule boste dobili vrednost napake #DIV/0, če seznam podatkov vsebuje prazne celice. Če želite popraviti in prezreti prazne celice, morate uporabiti eno od spodnjih formul:
    Formula 1: Po vnosu formule pritisnite Vnesite ključ.
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))        
    Formula 2: Po vnosu formule pritisnite Ctrl + Shift + Enter ključi.
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))       

  3. Da pridobi samo število različnih besedilnih vrednosti na seznamu podatkov uporabite spodnjo matrično formulo in pritisnite Ctrl + Shift + Enter ključi, da dobite rezultat:
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. Da šteti samo različne številske vrednosti, uporabite naslednjo matrično formulo in pritisnite Ctrl + Shift + Enter ključi, da dobite rezultat:
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

Preštejte različne vrednosti z nekaj kliki Kutools za Excel

Če morate formule v svojem delovnem zvezku pogosto uporabljati, vam bo morda boleče, če se boste spomnili formul, ko jih boste naslednjič morali uporabiti. Ampak, če imate Kutools za Excel, Z njegovim Štejte celice z edinstvenimi vrednostmi (vključite prvi dvojnik) možnost Pomočnik za formule, dobite rezultat z le nekaj kliki. Oglejte si spodnjo predstavitev:

  1. Kliknite celico, da izpišete rezultat;
  2. Omogočite to funkcijo s klikom Kutools > Pomočnik za formulo > Statistični > Preštejte edinstvene celice z edinstvenimi vrednostmi (vključite prvi dvojnik);
  3. Izberite seznam podatkov > OK.
nasveti:
  1. Če želite uporabiti to funkcijo, bi morali prenesite in namestite najprej.
  2. O Pomočnik za formule funkcija zbira 40+ pogosto uporabljenih formul, kot je npr Izvlecite edinstvene vrednosti, Ekstrahirajte celice z edinstvenimi vrednostmi (vključite prve dvojnike), Preštejte število vrednosti, ločenih z vejico, Vsota na podlagi istega besedila, in več...

Preštejte različne vrednosti z vrtilno tabelo

V Excelu lahko vrtilna tabela tudi pomaga pridobiti število različnih vrednosti s seznama podatkov, sledite tem korakom:

1. korak: Ustvarite vrtilno tabelo

  1. Izberite seznam podatkov in kliknite Vstavi > Vrteča miza s traku si oglejte posnetek zaslona:
  2. V izskočil Vrteča miza iz pogovornega okna tabele ali obsega:
    (1). Izberite nov delovni list ali obstoječi delovni list, kamor želite postaviti vrtilno tabelo;
    (2). Potem preveri Te podatke dodajte v podatkovni model potrditveno polje.
    (3). Nato kliknite OK gumb.

2. korak: Uredite polje in izberite možnost Različno štetje

  1.  A Polja vrtilne tabele se prikaže podokno, povlecite imena polje v Vrednote območje, glejte spodnjo predstavitev:
  2. Nato kliknite na Število imen spustite in izberite Nastavitve polja vrednosti, glej posnetek zaslona:
  3. In potem, a Nastavitve polja vrednosti Odpre se pogovorno okno, izberite Izrazit grof iz polja s seznamom pod Povzemite vrednost po in kliknite OK gumb, glej posnetek zaslona:

Rezultat:

Zdaj bo ustvarjena vrtilna tabela prikazala razločno število seznama podatkov, kot je prikazano na spodnjem posnetku zaslona:

nasveti:

  1. Če posodobite izvorne podatke, morate za pridobitev najnovejšega števila samo z desno miškino tipko klikniti vrtilno tabelo in izbrati Osveži možnost.
  2. Ta Izrazit grof možnost je na voljo samo v Excelu 2013 in novejših.

Preštejte različne vrednosti v Excelu 365/2021 s formulami

V Excelu 365 ali Excelu 2021 lahko uporabite novo funkcijo UNIQUE z običajno funkcijo COUNTA, da ustvarite preprosto formulo.

Kopirajte ali vnesite spodnjo formulo v prazno celico in pritisnite Vnesite ključ do rezultata:

=COUNTA(UNIQUE(A2:A12)) 
Opombe: V tej formuli, A2: A12 je seznam podatkov, za katerega želite šteti različne vrednosti.

nasveti:

  1. Če seznam podatkov vsebuje druge vrste podatkov, kot so besedilo, števila, logične vrednosti, vrednosti napak itd., bo ta formula preštela število različnih vrednosti ne glede na vrsto podatkov.
  2. Zgornja formula bo štela različne vrednosti, vključno s praznimi celicami. Če želite izključiti prazne celice, uporabite spodnjo formulo in pritisnite Vnesite ključ do rezultata:
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))    


Sorodni članki:

  • Štejte edinstvene vrednosti v vrtilni tabeli
  • Privzeto se pri ustvarjanju vrtilne tabele, ki temelji na obsegu podatkov, ki vsebujejo nekaj podvojenih vrednosti, štejejo tudi vsi zapisi, včasih pa želimo samo prešteti edinstvene vrednosti na podlagi enega stolpca, da dobimo pravo rezultat posnetka zaslona. V tem članku bom govoril o tem, kako šteti edinstvene vrednosti v vrtilni tabeli.
  • Preštejte edinstvene vrednosti v filtriranem stolpcu
  • Če imate seznam imen, ki so v filtriranem stolpcu zapolnjeni z nekaj dvojniki, zdaj želite prešteti število edinstvenih imen samo s tega filtriranega seznama. Ali imate dobre rešitve za hitro reševanje tega dela v Excelu?
  • Preštejte edinstvene vrednosti z več kriteriji
  • Tu je vrsta podatkov, ki vsebujejo več imen, projektov in lokacij, zato je treba poiskati imena, ki ustrezajo merilom, ki jih imam na seznamu, in nato vsaka ujemajoča se imena enkrat prešteti le, kot je prikazano na spodnji sliki zaslona. Imate kakšen trik pri reševanju tega dela? V tem članku bom predstavil trike.
  • Združite edinstvene vrednosti
  • Če imam dolg seznam vrednosti, ki je zapolnjen z nekaj podvojenimi podatki, želim zdaj najti samo edinstvene vrednosti in jih nato združiti v eno celico. Kako sem se lahko hitro in enostavno spopadel s to težavo v Excelu?
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations