Kako šteti člane distribucijskega seznama v Outlooku?

V Outlooku ni funkcije za neposredno štetje članov distribucijskega seznama. Če imate seznam razdeljevanja z veliko e-poštnimi naslovi, kako ugotoviti, koliko članov je vključenih v to skupino? V tem članku boste izvedeli, kako šteti člane distribucijskega seznama z uporabo kode VBA.

Štejte člane seznama za distribucijo v Outlooku s kodo VBA

Ustvarite in shranite kodo VBA

V orodno vrstico za hitri dostop dodajte gumb za makro

Zaženite kodo VBA

Štejte člane seznama za distribucijo v Outlooku s kodo VBA

Kodo VBA lahko uporabite za štetje članov distribucijskega seznama, kot sledi.

Ustvarite in shranite kodo VBA

1. Odprite Microsoft Visual Basic za aplikacije okno s pritiskom na druga + F11 tipke na tipkovnici hkrati.

2. klik Vstavi > Moduli. Oglejte si posnetek zaslona:

3. Nato kopirajte in prilepite naslednjo kodo VBA v VbaProject okno.

VBA: Štetje članov distribucijskega seznama v programu Outlook

Sub CountDLMembers()
    Dim oOL As Outlook.Application
    Dim oSelection As Outlook.Selection
    Dim oItem As Object
    Dim olDL As Outlook.DistListItem
    Dim Result As String
    Set oOL = Outlook.Application
    'Check and get the selected Contact Group
    Select Case TypeName(oOL.ActiveWindow)
        Case "Explorer"
            Set oSelection = oOL.ActiveExplorer.Selection
            If oSelection.Count > 0 Then
                Set oItem = oSelection.Item(1)
            Else
                Result = MsgBox("No item selected. " & _
                            "Please select a Contact Group first.", _
                            vbCritical, "CountDLMembers")
                Exit Sub
            End If
        Case "Inspector"
            Set oItem = oOL.ActiveInspector.CurrentItem
        Case Else
            Result = MsgBox("Unsupported Window type." & _
                        vbNewLine & "Please make a selection" & _
                        "in the Calendar or open a Contact Group first.", _
                        vbCritical, "CountDLMembers")
            Exit Sub
    End Select
    If oItem.Class = Outlook.olDistributionList Then
        'Display the member count
        Set olDL = oItem        
        Result = MsgBox("The Contact Group '" & olDL.DLName & "' contains " & olDL.MemberCount & " members.", vbInformation, "CountDLMembers")
    Else
        'Selected item isn't a Contact Group item
        Result = MsgBox("No Contact Group item selected. " & _
                    "Please make a selection first.", _
                    vbCritical, "CountDLMembers")
        Exit Sub
    End If
    'Cleanup
    Set oOL = Nothing
    Set olDL = Nothing
End Sub

4. Nato kliknite na Shrani gumb, da ga shranite.

5. Zaprite Microsoft Visual Basic za aplikacije okno.

V orodno vrstico za hitri dostop dodajte gumb za makro

1. Pojdi Kontakti or ljudje pogled s klikom na Kontakti or ljudje v Podokno za krmarjenje.

2. V Outlook 2010 in 2013 z desno miškino tipko kliknite Orodna vrstica za hitri dostop In nato kliknite Prilagodite orodno vrstico za hitri dostop v meniju z desnim klikom. Oglejte si posnetek zaslona:

Opombe: V programu Outlook 2007 odprite seznam distribucije in z desno miškino tipko kliknite Orodna vrstica za hitri dostop da izberete Orodna vrstica za hitri dostop v meniju z desnim klikom.

3. V Ljubljani Outlook Možnosti pogovorno okno, morate:

1). Prepričajte se, da iščete v Orodna vrstica za hitri dostop odsek;

2). Izberite Makri v Izberite ukaze iz spustni seznam;

3). Izberite makre v separator škatla;

4). Kliknite Dodaj gumb;

5). In končno kliknite OK . Oglejte si posnetek zaslona:

4. Nato lahko vidite, da je gumb za makro dodan na Orodna vrstica za hitri dostop.

Zaženite kodo VBA

Po dodajanju gumba za makro v orodni vrstici za hitri dostop lahko zdaj zaženete kodo VBA za štetje članov distribucijskega seznama.

1. V programih Outlook 2010 in 2013 lahko preprosto izberete seznam za distribucijo in nato kliknete gumb za makro na Quick Access Toolbar.

Opombe: V programu Outlook 2007 morate odpreti seznam za distribucijo in nato klikniti gumb za makro na Orodna vrstica za hitri dostop.

2. Nato se prikaže pozivno okno, ki vam pove, koliko članov je na tem seznamu distribucije. Nato kliknite OK.