Kako pridobiti informacije o seznamu prilog v izbrani pošti v Outlook?

Za prejeta e-poštna sporočila, ki so priložena s priponkami, boste včasih morda morali poznati podrobne informacije o priponkah, kot je prikazno ime, ime datoteke itd. Pravzaprav vam lahko koda VBA pomaga enostavno pridobiti informacije o seznamu prilog v trenutno izbranem e-poštnem sporočilu Outlook. Za več podrobnosti prebrskajte spodnjo vadnico.

Pridobite informacije o seznamu prilog v izbrani pošti v Outlook

Pridobite informacije o seznamu prilog v izbrani pošti v Outlook

1. Izberite e-poštno sporočilo s prilogami, za katere želite dobiti informacije o njih.

2. Pritisnite druga + F11 tipke na tipkovnici, da odprete Microsoft Visual Basic za aplikacije okno.

3. Nato dvokliknite Project1 > Microsoft Outlook predmet > TaOutlookSession da odprete Projekt1 – ToOutlookSession okno. Oglejte si posnetek zaslona:

4. Nato kopirajte in prilepite spodnjo kodo VBA v Project1 – ThisOutlookOkno seje.

Koda VBA: pridobite seznam informacij o prilogah

Option Explicit
Public Sub GetAttachmentList()
    Dim selItem As Object
    Dim aMail As MailItem
    Dim aAttach As attachment
    Dim Report As String
    
    For Each selItem In Application.ActiveExplorer.Selection
        If selItem.Class = olMail Then
            Set aMail = selItem
            For Each aAttach In aMail.Attachments
                Report = Report & vbCrLf & "------------------------------------------------------------------------" & vbCrLf
                Report = Report & GetAttachmentInfo(aAttach)
            Next
            Call CreateReportEmail("Attachment Report", Report)
        End If
    Next
End Sub
 
Public Function GetAttachmentInfo(attachment As attachment)
    Dim Report
    GetAttachmentInfo = ""
    Report = Report & "Index: " & attachment.Index & vbCrLf
    Report = Report & "Display Name: " & attachment.DisplayName & vbCrLf
    Report = Report & "File Name: " & attachment.FileName & vbCrLf
    Report = Report & "Block Level: " & attachment.BlockLevel & vbCrLf
    Report = Report & "Path Name: " & attachment.PathName & vbCrLf
    Report = Report & "Position: " & attachment.Position & vbCrLf
    Report = Report & "Size: " & attachment.Size & vbCrLf
    Report = Report & "Type: " & attachment.Type & vbCrLf
    
    GetAttachmentInfo = Report
End Function
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub 

5. Pritisnite F5 tipko na tipkovnici za zagon kode VBA.

6. Zdaj a Makri Pojavi se pogovorno okno, kliknite Run gumb.

7. Po kliku na Run gumb v Makri V pogovornem oknu bo ustvarjeno novo okno s sporočili z vsemi informacijami o prilogah izbranega e-poštnega sporočila, ki so navedene znotraj telesa e-pošte. Oglejte si posnetek zaslona:

Opombe: To kodo VBA je mogoče uporabiti za Outlook 2007, 2010 in 2013