Kako natisniti opravila glede na kategorijo v Outlooku?

Recimo, da so v vaših opravilih v Outlooku različne barvne kategorije, zdaj pa želite natisniti sezname opravil glede na kategorije na različnih straneh. Kako ste lahko rešili to nalogo v Outlooku?

Ročno tiskajte naloge na podlagi kategorij na različnih straneh

Natisnite opravila na podlagi kategorij na različnih straneh s kodo VBA

Ročno tiskajte naloge na podlagi kategorij na različnih straneh

V Outlooku lahko ročno tiskate naloge na podlagi različnih kategorij na različnih straneh, eno za drugo, naredite tako:

1. Zaženite Outlook, pojdite na podokno opravil in izberite mapo opravil, ki jo želite natisniti, nato pritisnite Ctrl + E za vklop Iskalnik in nato pod Iskalnik jeziček, kliknite Kategorizirani ikono in izberite eno barvno kategorijo, ki jo želite natisniti, glejte posnetek zaslona:

doc tiskanje opravil po kategoriji 1

2. Nato so naenkrat naštete vse naloge z določeno barvno kategorijo, glejte posnetek zaslona:

doc tiskanje opravil po kategoriji 2

3. Nato nadaljujte s klikom file > Tiskanje da natisnete ta seznam opravil, kot je prikazano na sliki spodaj:

doc tiskanje opravil po kategoriji 3

4. Ponovite zgornje korake, da ročno natisnete sezname opravil z drugimi barvnimi kategorijami.

Natisnite opravila na podlagi kategorij na različnih straneh s kodo VBA

Tukaj je koda VBA, ki vam lahko pomaga natisniti naloge glede na kategorijo na različne strani hkrati, naredite naslednje:

1. Pojdi na Naloga in izberite mapo opravil, ki jo želite natisniti.

2. Nato držite tipko ALT + F11 tipke za odpiranje Microsoft Visual Basic za aplikacije okno.

3. In nato kliknite Vstavi > Moduli, kopirajte in prilepite spodnjo kodo v odprti prazen modul:

Koda VBA: Natisnite naloge na podlagi kategorij na različnih straneh:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Nato kliknite Orodja > Reference v Microsoft Visual Basic za aplikacije okno, v izpuščenem Reference-Projekt1 pogovorno okno, preverite Knjižnica predmetov Microsoft Excel in Izvajanje Microsoftovih skriptov možnosti iz Razpoložljive reference seznam, glej posnetek zaslona:

doc tiskanje opravil po kategoriji 4

5. In nato kliknite OK gumb, zdaj pritisnite F5 ključ za zagon te kode; po končani kodi se bodo seznami nalog z različnimi kategorijami natisnili na različne strani.