Kako pridobiti e-poštni naslov pošiljatelja iz enega ali več e-poštnih sporočil v Outlooku?

Ste že kdaj poskusili izvleči e-poštni naslov iz polja »Od« enega ali več prejetih e-poštnih sporočil v Outlooku? Ta članek ponuja kodo VBA, ki vam bo v pomoč pri reševanju te naloge.

Pridobite e-poštni naslov pošiljatelja iz enega ali več e-poštnih sporočil v Outlooku

Zaženite naslednjo kodo VBA, da izvlečete e-poštni naslov iz polja »Od« enega ali več prejetih e-poštnih sporočil v Outlooku.

1. Odprite e-poštno mapo, izberite e-poštno sporočilo, iz katerega želite pridobiti e-poštni naslov pošiljatelja. Pritisnite druga + F11 tipke za odpiranje Microsoft Visual Basic za aplikacije okno.

nasveti: Če želite izbrati več e-poštnih sporočil, pridržite Ctrl in nato enega za drugim izberite e-poštna sporočila.

2. V Ljubljani Microsoft Visual Basic za aplikacije okno, kliknite Vstavi > Moduli, nato kopirajte naslednjo kodo VBA v okno Module (code).

Koda VBA: izvlecite e-poštni naslov pošiljatelja iz enega ali več e-poštnih sporočil v Outlooku

Sub GetSmtpAddressOfSelectionEmail()
  Dim xExplorer As Explorer
  Dim xSelection As Selection
  Dim xItem As Object
  Dim xMail As MailItem
  Dim xAddress As String
  Dim xFldObj As Object
  Dim FilePath As String
  Dim xFSO As Scripting.FileSystemObject
  On Error Resume Next
  Set xExplorer = Application.ActiveExplorer
  Set xSelection = xExplorer.Selection
  For Each xItem In xSelection
    If xItem.Class = olMail Then
      Set xMail = xItem
      xAddress = xAddress & VBA.vbCrLf & "  " & GetSmtpAddress(xMail)
    End If
  Next
  If MsgBox("Sender SMTP Address is: " & xAddress & vbCrLf & vbCrLf & "Do you want to export the address list to a txt file? ", vbYesNo, "Kutools for Outlook") = vbYes Then
    Set xFldObj = CreateObject("Shell.Application").BrowseforFolder(0, "Select a Folder", 0, 16)
    Set xFSO = New Scripting.FileSystemObject
    If xFldObj Is Nothing Then Exit Sub
    FilePath = xFldObj.Items.Item.Path & "\Address.txt"
    Close #1
    Open FilePath For Output As #1
    Print #1, "Sender SMTP Address is: " & xAddress
    Close #1
    Set xFSO = Nothing
    Set xFldObj = Nothing
    MsgBox "Address list has been exported to：" & FilePath, vbOKOnly + vbInformation, "Kutools for Outlook"
  End If
End Sub
Function GetSmtpAddress(Mail As MailItem)
  Dim xNameSpace As Outlook.NameSpace
  Dim xEntryID As String
  Dim xAddressEntry As AddressEntry
  Dim PR_SENT_REPRESENTING_ENTRYID As String
  Dim PR_SMTP_ADDRESS As String
  Dim xExchangeUser As exchangeUser
  On Error Resume Next
  GetSmtpAddress = ""
  Set xNameSpace = Application.Session
  If Mail.sender.Type <> "EX" Then
    GetSmtpAddress = Mail.sender.Address
  Else
    PR_SENT_REPRESENTING_ENTRYID = "http://schemas.microsoft.com/mapi/proptag/0x00410102"
    xEntryID = Mail.PropertyAccessor.BinaryToString(Mail.PropertyAccessor.GetProperty(PR_SENT_REPRESENTING_ENTRYID))
    Set xAddressEntry = xNameSpace.GetAddressEntryFromID(xEntryID)
    If xAddressEntry Is Nothing Then Exit Function
    If xAddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Or xAddressEntry.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
      Set xExchangeUser = xAddressEntry.GetExchangeUser()
      If xExchangeUser Is Nothing Then Exit Function
      GetSmtpAddress = xExchangeUser.PrimarySmtpAddress
    Else
      PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
      GetSmtpAddress = xAddressEntry.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    End If
  End If
End Function

3. klik Orodja > Reference, nato preverite Izvajanje Microsoftovih skriptov polje v Reference – Projekt1 pogovorno okno.

4. Pritisnite F5 tipko za zagon kode. Potem a Kutools for Outlook se prikaže pogovorno okno s seznamom vseh e-poštnih naslovov pošiljatelja izbranih e-poštnih sporočil.

nasveti:

5. Po kliku na Da gumb, a Brskaj po mapi se prikaže pogovorno okno. Izberite mapo za shranjevanje datoteke in kliknite OK gumb.

6. Končno, a Kutools for Outlook se bo pojavilo pogovorno okno, ki vam bo povedalo pot do izvožene datoteke. Kliknite OK da ga zaprete.

7. Pojdite v mapo, kjer je shranjena izvožena datoteka, in odprite imenovano datoteko .txt Naslov: da vidite e-poštne naslove pošiljatelja izbranih e-poštnih sporočil.