Outlook: Kako obdržati preklican sestanek v koledarju kot organizator?

Ko v Outlooku kot organizator sestanka prekličete sestanek, bo sestanek samodejno izbrisan iz koledarja. V nekaterih primerih boste morda želeli obdržati preklicane sestanke v koledarju, da naredite nekaj oznak. Vendar v Outlooku ni vgrajenih funkcij, ki bi lahko opravile to nalogo. V tej vadnici ponuja dve kodi VBA za ohranjanje sestanka kot sestanka med preklicem.

Kode VBA za kopiranje preklicanega sestanka kot sestanka

Kode VBA za kopiranje preklicanega sestanka kot sestanka

Tu sta dve kodi za preklic sestanka in istočasno kopiranje in lepljenje kot sestanek.

Opomba: preden omogočite kodo, se prepričajte, da sta ti dve možnosti označeni:

Omogočite Outlook, kliknite file > možnosti, kliknite v oknu Outlookove možnosti Trust Center in kliknite Trust Center Nastavitve, nato v oknu Središča zaupanja kliknite Nastavitve makrov tab, preveri Omogoči vse makre (ni priporočljivo; lahko se zažene potencialno nevarna koda) in Uporabite varnostne nastavitve makrov za nameščene dodatke opcije. Kliknite OK > OK zapreti okna. Restart obeti.

1. Pomaknite se do pogleda koledarja Outlook in izberite srečanje, ki ga želite preklicati. Pritisnite druga + F11 tipke za omogočanje okna Microsoft Visual Basic for Applications.

2. klik Vstavi > Moduli da vstavite nov prazen modul. Nato vanj kopirajte in prilepite spodnjo kodo.

Koda: Kopirajte sestanek kot sestanek in ga prekličite

Sub CopyMeetingAsAppointmentBeforeCancel()
'UpdatebyExtendoffice20221129
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move Application.ActiveExplorer.CurrentFolder
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

3. klik Run ali pritisnite F5 tipko, zdaj je bil izbrani sestanek preklican in nov sestanek z imenom Preklican & subjekt.

Če želite kopirati in prilepiti sestanek kot sestanek v drug koledar in nato preklicati sestanek, uporabite spodnjo kodo:

Koda: Kopirajte sestanek kot sestanek v drug koledar in ga prekličite

Sub CopyMeetingAsAppointmentToCalenderBeforeCancel()
'Updatebyextendoffice20221129
Dim xDestCalendar As Outlook.MAPIFolder
Dim xNameSpace As Outlook.NameSpace
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xNameSpace = Application.GetNamespace("MAPI")
Set xDestCalendar = xNameSpace.PickFolder
If xDestCalendar.DefaultItemType <> olAppointmentItem Then
  MsgBox "Please Select calendar folder. ", vbOKOnly + vbInformation, "Kutools for Outlook"
  Exit Sub
End If
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move xDestCalendar
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xDestCalendar = Nothing
Set xNameSpace = Nothing
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

klik Run ali pritisnite F5 tipko, se prikaže pogovorno okno Izberi mapo, v katerem lahko izberete mapo koledarja, v katero želite prilepiti sestanek, nato pa kliknite V redu.