Note: The other languages of the website are Google-translated. Back to English

Razdelite dimenzije na posamezne dolžine, višine in širine

V tem članku je razloženo, kako razdeliti dimenzije v celici na tri dele (posamezne dimenzije, ki vključujejo dolžino, višino in širino).


Kako razdeliti dimenzije na tri dele?

Če želite dimenzije razdeliti na posamezne dolžine, višine in širine, morate ločeno uporabiti tri različne formule.

Splošna formula za pridobivanje prve dimenzije

=LEFT(text,FIND("char",text)-1)

Splošna formula za pridobivanje druge dimenzije

=MID(text,FIND("char",text)+1,FIND("@",SUBSTITUTE(text,"char","@",2))-(FIND("char",text)+1))

Splošna formula za pridobivanje tretje dimenzije

=RIGHT(text,LEN(text)-FIND("@",SUBSTITUTE(text,"char","@",2)))

Argumenti zgornjih formul

Besedilo: Niz, iz katerega želite izvleči določeno število znakov. Lahko je:

  • 1. Besedilo v narekovajih;
  • 2. Ali sklic na celico, ki vsebuje besedilo.

znak: Znak, na podlagi katerega boste razdelili dimenzije.

Kako uporabiti te formule?

Najprej moramo dobiti prvo dimenzijo.

1. Izberite prazno celico, da izpišete prvo dimenzijo.

2. Vanjo vnesite spodnjo formulo in pritisnite Vnesite tipko. Če izberete celico z rezultatom, povlecite ročico za izpolnjevanje, da formulo uporabite po potrebi v drugih celicah.

=LEFT(B5,FIND("x",B5)-1)

Nato bomo drugo dimenzijo razdelili na naslednji način.

1. Izberite prazno celico, da izpišete drugo dimenzijo.

2. Vanjo vnesite spodnjo formulo in pritisnite Vnesite tipko. Če izberete celico z rezultatom, povlecite ročico za izpolnjevanje, da formulo uporabite po potrebi v drugih celicah.

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

Končno dobite še zadnjo dimenzijo

1. Izberite prazno celico, da izpišete zadnjo dimenzijo.

2. Vanjo vnesite spodnjo formulo in pritisnite Vnesite tipko. Če izberete celico z rezultatom, povlecite ročico za izpolnjevanje, da formulo uporabite po potrebi v drugih celicah.

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

Kako te formule delujejo?

=LEFT(B5,FIND("x",B5)-1)

1. FIND("x",B5)-1: Funkcija FIND dobi položaj prvega "x" v B5. Če želite dobiti prvo dimenzijo brez prvega "x", morate odšteti 1. Potem je rezultat 4-1 = 3.
2. LEFT(B5,3): Leva funkcija izvleče 3 znake, začenši z leve strani B5, in vrne rezultat kot 100.

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

1. FIND("x",B5)+1: Funkcija FIND poišče prvi "x" B5. Ker morate po prvem "x" dobiti drugo dimenzijo, je tukaj treba dodati 1. Potem je rezultat 4 + 1 = 5.
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

  • SUBSTITUTE(B5,"x","@",2): Funkcija SUBSTITUTE nadomesti drugi "x" v B5 z "@" in vrne rezultat kot 100x50 @ 300;
  • FIND("@",100x50@300): Tu najde funkcija FIND položaj znaka "@" v besedilu 100x50 @ 300 in rezultat vrne kot 7.

3. (FIND("x",B5)+1): Kot je omenjen zgoraj v koraku 1, tukaj funkcija FIND poišče prvi "x" B5 in doda 1, da vrne rezultat kot 5.
4. MID(B5,5,7-(5)): Funkcija MID izvleče dva znaka (7-5 ​​= 2), začenši s petim znakom besedila v B5. In vrnite končni rezultat kot 50.

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

1. LEN(B5): Funkcija LEN izračuna skupno dolžino niza v B5 in vrne rezultat kot 10;
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

  • SUBSTITUTE(B5,"x","@",2): Funkcija SUBSTITUTE nadomesti drugi "x" v B5 z "@" in vrne rezultat kot 100x50 @ 300;
  • FIND("@",100x50@300): Funkcija FIND tukaj najde "@" v besedilu 100x50 @ 300 in rezultat vrne kot 7.

3. LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)): (10–7) Skupna dolžina besedilnega niza v celici B5 odšteje prvih 7 znakov in rezultat vrne kot 3.
4. RIGHT(B5,3): Nato funkcija DESNO izvleče 3 znake, začenši z desne strani B5, in vrne tretjo dimenzijo kot 300.


Sorodne funkcije

Excel LEFT funkcija
Funkcija LEVO izvleče določeno število znakov z leve strani dobavljenega niza.

Excel MID funkcija
Funkcija MID se uporablja za iskanje in vrnitev določenega števila znakov iz sredine danega besedilnega niza.

Excel DESNA funkcija
Funkcija DESNO izvleče določeno število znakov z desne strani besedilnega niza.

Excel FIND funkcija
Funkcija FIND se uporablja za iskanje niza v drugem nizu in vrne začetni položaj niza znotraj drugega.

Excel LEN funkcija
Funkcija LEN vrne število znakov v besedilnem nizu.

Funkcija Excel SUBSTITUTE
Funkcija Microsoft Excel SUBSTITUTE nadomesti besedilo ali znake v besedilnem nizu z drugim besedilom ali znaki.


Sorodne formule

Razdelite dimenzije na dva dela v Excelu
Ta članek razlaga, kako uporabiti formulo za razdelitev dimenzij v celici na dva dela brez enot (posamezna dolžina in širina).

Številke ločite od merskih enot
V tem članku je razloženo, kako s formulo ločiti številke od merilnih enot.


Najboljša orodja za pisarniško produktivnost

Kutools za Excel - vam pomaga izstopati iz množice

Bi radi svoje vsakodnevno delo opravili hitro in popolno? Kutools za Excel prinaša 300 zmogljivih naprednih funkcij (združevanje delovnih zvezkov, seštevanje po barvi, razdelitev vsebine celice, pretvorba datuma itd.) in vam prihrani 80 % časa.

  • Zasnovan za 1500 delovnih scenarijev vam pomaga rešiti 80 % Excelovih težav.
  • Vsak dan zmanjšajte na tisoče klikov na tipkovnici in miški, razbremenite utrujene oči in roke.
  • V 3 minutah postanite strokovnjak za Excel. Ni vam več treba zapomniti nobenih bolečih formul in kod VBA.
  • 30-dnevno neomejeno brezplačno preskusno obdobje. 60-dnevno jamstvo za vračilo denarja. Brezplačna nadgradnja in podpora za 2 leti.
Trak Excela (z nameščenim Kutools za Excel)

Kartica Office - omogočite branje in urejanje z zavihki v programu Microsoft Office (vključite Excel)

  • Eno sekundo za preklop med desetinami odprtih dokumentov!
  • Vsak dan zmanjšajte na stotine klikov z miško, poslovite se od roke miške.
  • Poveča vašo produktivnost za 50% pri ogledu in urejanju več dokumentov.
  • Prinaša učinkovite zavihke v Office (vključno z Excelom), tako kot Chrome, Firefox in New Internet Explorer.
Posnetek zaslona programa Excel (z nameščenim zavihkom Office)
Komentarji (0)
Ocene še ni. Bodite prvi in ​​ocenite!
Tu še ni objavljenih komentarjev
Pustite vaše komentarje
Objava kot gost
×
Ocenite to objavo:
0   Znaki
Predlagane lokacije

Sledi nam

Copyright © 2009 - www.extendoffice.com. | Vse pravice pridržane. Poganja ga ExtendOffice. | Kazalo
Microsoft in logotip Office sta blagovni znamki ali registrirani blagovni znamki družbe Microsoft Corporation v ZDA in / ali drugih državah.
Zaščiteno s Sectigo SSL