Razdeli besedilni niz na določen znak v celici v Excelu
V tej vadnici je razloženo, kako razdeliti niz besedil z določenim znakom v ločene celice stolpcev s formulami v Excelu.
Kako razdeliti besedilni niz na določen znak v celici v Excelu?
Recimo, da imate v spodnjem posnetku zaslona seznam besedilnih nizov v stolpcu B in želite besedila razdeliti na znak »-« in jih prikazati v treh ločenih stolpcih. V tem primeru vam lahko spodnje formule naredijo uslugo.
Splošne formule
Splošna formula za razdelitev levega besedila
=LEFT(text_string,FIND("Char", text_string)-1)
Splošna formula za razdelitev srednjega besedila
=MID(text_string, FIND("Char", text_string) + 1, FIND("Char", text_string,FIND("Char", text_string)+1) - FIND("Char", text_string) - 1)
Splošna formula za razdelitev pravega besedila
=RIGHT(text_string,LEN(text_string) - FIND("Char", text_string, FIND("Char", text_string) + 1))
Argumenti zgornjih formul
Niz besedila: Besedilni niz, iz katerega želite razdeliti besedilo;
kočija: Znak, na podlagi katerega boste razdelili besedilo.
Kako uporabiti te formule?
Najprej razdelite prvi besedilni niz glede na določen znak
1. Izberite prazno celico za prikaz rezultata. Tu izberem C3.
2. Vanjo vnesite spodnjo formulo in pritisnite Vnesite tipko. Nato povlecite celico s formulo LEVO do konca, da jo uporabite za druge celice.
=LEFT(B3,FIND("-",B3)-1)
Drugič, razdelite srednji besedilni niz glede na določen znak
1. Za prazen rezultat izberite prazno celico, kot je D3.
2. Vanjo vnesite spodnjo formulo in pritisnite Vnesite tipko. Izberite celico z rezultatom, povlecite ročico za izpolnjevanje navzdol, da formulo uporabite v drugih celicah.
=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)
Na koncu razdelite še zadnji besedilni niz glede na določen znak
1. Za prazen rezultat izberite prazno celico, na primer E3.
2. Vanjo vnesite spodnjo formulo in pritisnite Vnesite tipko. Izberite celico z rezultatom, povlecite ročico za izpolnjevanje navzdol, da formulo uporabite v drugih celicah.
=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))
Zdaj je besedilni niz v vsaki celici stolpca B razdeljen na tri dele.
nasveti: Če želite besedilni niz razdeliti samo na dva dela glede na določen znak, lahko po razdelitvi prvega dela z zgornjo LEVO formulo uporabite spodnjo DESNO formulo, da izvlečete drugi del, kot je prikazano na spodnji sliki zaslona.
=RIGHT(B3,LEN(B3)-FIND("-",B3))
Kako te formule delujejo?
=LEFT(B3,FIND("-",B3)-1)
- FIND("-",B3): Funkcija FIND vrne začetni položaj znaka "-" v besedilnem nizu KTE-Jan-359. Rezultat je 4.
- LEFT(B3,4-1): Leva funkcija izvleče 3 znake (4-1 = 3) z leve strani besedilnega niza KTE-Jan-359. Tu je rezultat KTE.
Opombe: Ker je prvi znak "-" na 4. mestu besedilnega niza, morate odšteti 1, da ga izključite iz ekstrahiranja.
=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)
- FIND("-",B3) + 1: Funkcija FIND vrne začetni položaj znaka "-" v besedilnem nizu KTE-Jan-359. Tu je rezultat 4.
Opombe: Ker je prvi znak "-" na 4. mestu besedilnega niza, morate dodati 1 do 4, da izvlečete besedila za njim, in končno zaključimo s 4 + 1 = 5. - FIND("-",B3,FIND("-",B3)+1) tukaj je prikazano kot FIND ("-", KTE-Jan-359,4 + 1): Funkcija Find najde položaj znaka "-", začenši od 5. znaka v KTE-Jan-359. In vrne rezultat kot 8.
- MID(B3, 5, 8 - 4 - 1): MID (KTE-Jan-359,5,3), kar pomeni, da funkcija MID izvleče 3 števila znakov, začenši s 5. znakom v besedilnem nizu KTE-Jan-359. In rezultat je Jan.
=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))
- LEN(B3): Funkcija LEN izračuna skupno dolžino besedilnega niza KTE-Jan-359 in rezultat vrne kot 11.
- FIND("-",B3,FIND("-",B3)+1): Funkcija Najdi najde položaj znaka "-" od 5. znaka v KTE-Jan-359. In vrne rezultat kot 8.
- RIGHT(B3,11 - 8)): Funkcija DESNO izvleče 3 (11–8) znakov z desne strani KTE-Jan-359. Tu je rezultat 359.
Sorodne funkcije
Excel LEFT funkcija
Funkcija LEVO izvleče določeno število znakov z leve strani dobavljenega niza.
Excel FIND funkcija
Funkcija FIND se uporablja za iskanje niza v drugem nizu in vrne začetni položaj niza znotraj drugega.
Excel MID funkcija
Funkcija MID se uporablja za iskanje in vrnitev določenega števila znakov iz sredine danega besedilnega niza.
Excel DESNA funkcija
Funkcija DESNO izvleče določeno število znakov z desne strani besedilnega niza.
Excel LEN funkcija
Funkcija Excel LEN vrne število znakov v besedilnem nizu.
Sorodne formule
Razdelite dimenzije na dva dela v Excelu
Ta članek razlaga, kako uporabiti formule za razdelitev dimenzij v celici na dva dela brez enot (posamezna dolžina in širina).
Številke ločite od merskih enot
V tem članku je razloženo, kako s formulo ločiti številke od merilnih enot.
Razdelite besedilo in številke v celici v Excelu
Če želite besedilo in številke v celici razdeliti na različne celice stolpcev s formulami, vam bo ta vadnica naredila uslugo.
Razdeljeno besedilo z ločilnikom v celici v Excelu
V tem članku ponujamo vodnik po korakih, ki vam bo pomagal razdeliti besedilo v celici s posebnim ločilom v Excelu.
Najboljša orodja za pisarniško produktivnost
Kutools za Excel - vam pomaga izstopati iz množice
Kutools za Excel se ponaša z več kot 300 funkcijami, Zagotavljanje, da je vse, kar potrebujete, le en klik stran ...
Kartica Office - omogočite branje in urejanje z zavihki v programu Microsoft Office (vključite Excel)
- Eno sekundo za preklop med desetinami odprtih dokumentov!
- Vsak dan zmanjšajte na stotine klikov z miško, poslovite se od roke miške.
- Poveča vašo produktivnost za 50% pri ogledu in urejanju več dokumentov.
- Prinaša učinkovite zavihke v Office (vključno z Excelom), tako kot Chrome, Edge in Firefox.