Kako samodejno označiti e-pošto glede na določeno prilogo v Outlook?

Ko prejmete nekatera e-poštna sporočila s posebno pomembno prilogo, jih boste morda morali označiti z zastavico, tako da jih boste lahko hitro in enostavno našli za nadaljnje priprave. V tem članku bom govoril o enostavnem načinu samodejnega označevanja e-poštnih sporočil s prilogami s posebnimi imeni.

Samodejno označi e-pošto na podlagi posebne priloge s kodo VBA

Samodejno označi e-pošto na podlagi posebne priloge s kodo VBA

Če želite samodejno označiti e-pošto, ki vsebuje določeno prilogo, uporabite naslednjo kodo VBA:

1. Zaženite Outlook in pridržite ALT + F11 tipke za odpiranje Microsoft Visual Basic za aplikacije okno.

2. v Microsoft Visual Basic za aplikacije okno, dvokliknite Ta OutlookSession Iz Projekt1 (VbaProject.OTM) , da odprete nov način, nato pa v prazen modul kopirajte in prilepite naslednjo kodo.

Koda VBA: Samodejno označi e-pošto glede na določeno prilogo:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"  'Add the file extension as you need
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then 'Change the text of the attachment name
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

Opombe: V zgornji kodi lahko spremenite končnico datoteke in ime datoteke priloge po vaših željah.

3. Nato shranite kodo in znova zaženite Outlook, da bo koda začela veljati. Ko prejmete e-pošto, katere imena prilog vsebujejo določeno besedilo, bo Outlook samodejno označil to e-pošto za nadaljnje ukrepanje, glejte sliko zaslona: