Kako normalno odgovoriti v mapi poslanih elementov iz Outlooka?

Ko v mapi Poslani elementi kliknete funkcijo Odgovori, da pošljete dodatno sporočilo osebam, ki ste jih poslali, bo v polju Za prikazan vaš e-poštni naslov, kot je prikazano na sliki spodaj. To vas lahko moti vsakič, ko spremenite naslov. Kako bi lahko Outlook uporabil naslov prvotnega prejemnika, ne vašega?

odgovor doc poslana e-poštna sporočila 1

Običajno odgovorite v mapi Poslani predmeti iz Outlooka s funkcijo Odgovori vsem

Običajno odgovorite v mapi Poslani predmeti iz Outlooka s kodo VBA

Običajno odgovorite v mapi Poslani predmeti iz Outlooka s funkcijo Odgovori vsem

V Outlooku je Odgovori vsem funkcija vam lahko pomaga rešiti to težavo, naredite naslednje:

Ko morate poslano e-poštno sporočilo odgovoriti na ponovno pošiljanje, da obdržite naslov prvotnega prejemnika, kliknite Odgovori vsem in naslov prvotnega prejemnika se nahaja na Da polje, kot je prikazano naslednja slika zaslona:

odgovor doc poslana e-poštna sporočila 2

Običajno odgovorite v mapi Poslani predmeti iz Outlooka s kodo VBA

Včasih boste morda pozabili Odgovori vsem pri odgovoru na poslano sporočilo, zato vam lahko spodnja koda VBA pomaga pri običajnem odgovoru v mapi Poslani s pomočjo funkcije Odgovori. Naredite naslednje:

1. Držite tipko ALT + F11 tipke za odpiranje Microsoft Visual Basic za aplikacije okno.

2. v Microsoft Visual Basic za aplikacije okno, dvokliknite Ta OutlookSession Iz Projekt1 (VbaProject.OTM) , da odprete način, nato pa v prazen modul kopirajte in prilepite naslednjo kodo.

Koda VBA: Običajno odgovorite v mapi Poslani predmeti iz Outlooka:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

odgovor doc poslana e-poštna sporočila 3

3. Nato shranite kodo in znova zaženite Outlook, da bo ob kliku sprožil učinek kode Odgovori za ponovno pošiljanje e-pošte v Poslani predmeti mape, se naslov prvotnega prejemnika prikaže v polju Za, kot ga potrebujete.