Kako odstraniti določeno vrsto prilog iz e-pošte v Outlooku?

Ste že kdaj poskusili odstraniti priloge iz več izbranih e-poštnih sporočil glede na vrsto datoteke v Outlooku? Na primer odstranjevanje vseh datotek prilog docx ali png iz izbranih e-poštnih sporočil. Kako ste lahko rešili to nalogo v Outlooku?

Odstranite določeno vrsto prilog iz e-pošte s kodo VBA

Odstranite določeno vrsto prilog iz e-pošte s kodo VBA

Če želite odstraniti določeno vrsto prilog iz izbranih e-poštnih sporočil, vam lahko naredite uslugo z naslednjo kodo VBA:

1. Na poštnem seznamu izberite e-pošto, za katero želite odstraniti njihovo posebno vrsto prilog.

2. Držite tipko ALT + F11 tipke za odpiranje Microsoft Visual Basic za aplikacije okno.

3. Nato kliknite Vstavi > Moduli, kopirajte in prilepite spodnjo kodo v odprti prazen modul, glejte posnetek zaslona:

Koda VBA: Odstranite določeno vrsto prilog iz e-pošte:

Sub DeleteSpecificTypeOfAttachments()
Dim xSelection As Outlook.Selection
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xAttachment As Outlook.Attachment
Dim xFileType As String
Dim xType As String
Dim xFSO As Scripting.FileSystemObject
Dim I As Integer
On Error Resume Next
Set xSelection = Outlook.Application.ActiveExplorer.Selection
Set xFSO = New Scripting.FileSystemObject
xType = ""
xType = InputBox("Attachment Type:", "Kutools for Outlook", xType, 8)
If Len(Trim(xType)) = 0 Then Exit Sub
For Each xItem In xSelection
    If xItem.Class = olMail Then
        Set xMailItem = xItem
       If xMailItem.Attachments.Count > 0 Then
            For I = xMailItem.Attachments.Count To 1 Step -1
                Set xAttachment = xMailItem.Attachments.Item(I)
                xFileType = xFSO.GetExtensionName(xAttachment.FileName)
                If InStr(xFileType, Trim(xType)) > 0 Then
                    xAttachment.Delete
                End If
            Next I
            xMailItem.Save
        End If
    End If
Next
Set xMailItem = Nothing
Set xFSO = Nothing
End Sub

4. In potem še vedno v Microsoft Visual Basic za aplikacije okno, kliknite Orodja > Reference Pojdite na Reference-Projekt1 pogovorno okno in preverite Izvajanje Microsoftovih skriptov možnost iz Razpoložljive reference seznam, glej posnetek zaslona:

doc odstrani priponko po tipu 1

5. Nato kliknite OK če želite zapreti pogovorno okno, pritisnite F5 tipko za zagon te kode in pojavilo se bo pozivno polje, vnesite vrsto priloge, ki jo želite odstraniti, glejte posnetek zaslona:

doc odstrani priponko po tipu 2