Kako obdržati kategorijo med odgovarjanjem ali posredovanjem e-pošte v Outlooku? 

Ko odgovorite ali posredujete e-poštno sporočilo, ki sem ga kategoriziral, se kategorija samodejno odstrani iz poslanega e-poštnega sporočila. Če želite obdržati kategorijo na odhodnih e-poštnih sporočilih pri odgovarjanju ali posredovanju, bo ta članek uvedel način obravnave.

Med odgovorom ali posredovanjem e-pošte s kodo VBA obdržite kategorijo

Med odgovorom ali posredovanjem e-pošte s kodo VBA obdržite kategorijo

1. Drži dol ALT + F11 tipke za odpiranje Microsoft Visual Basic za aplikacije okno.

2. v Microsoft Visual Basic za aplikacije okno, dvokliknite Ta OutlookSession Iz Projekt1 (VbaProject.OTM) , da odprete način, nato pa v prazen modul kopirajte in prilepite naslednjo kodo.

Koda VBA: Med odgovorom ali posredovanjem e-pošte obdržite kategorijo:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Nato shranite in zaprite to okno s kodo, zaprite in znova zaženite Outlook, zdaj, ko odgovorite ali posredujete e-poštno sporočilo s kategorijo, bo kategorija zadržana v odhodnem sporočilu Poslani predmeti, glej posnetek zaslona: