Kako poslati več osnutkov hkrati v Outlooku?

Če je v mapi Osnutki več osnutkov sporočil in jih želite poslati naenkrat, ne da bi jih pošiljali posebej. Kako bi se lahko v Outlooku hitro in enostavno spopadli s tem delom?

Vsa osnutka sporočil pošljite hkrati v Outlooku s kodo VBA

Vsa osnutka sporočil pošljite hkrati v Outlooku s kodo VBA

Naslednje kode VBA vam lahko pomagajo pri pošiljanju vseh ali izbranih osnutkov e-poštnih sporočil iz mape Osnutki hkrati. Naredite to:

1. Držite tipko ALT + F11 tipke za odpiranje Microsoft Visual Basic za aplikacije okno.

2. Nato kliknite Vstavi > Moduli, kopirajte in prilepite spodnjo kodo v odprti prazen modul, glejte posnetek zaslona:

Koda VBA: V Outlooku pošljite vsa osnutka e-poštnih sporočil hkrati:

Sub SendAllDraftEmails()
Dim xAccount As Account
Dim xDraftFld As Folder
Dim xItemCount As Integer
Dim xCount As Integer
Dim xDraftsItems As Outlook.Items
Dim xPromptStr As String
Dim xYesOrNo As Integer
Dim i As Long
Dim xCurFld As Folder
Dim xTmpFld As Folder
On Error Resume Next
xItemCount = 0
xCount = 0
Set xTmpFld = Nothing
Set xCurFld = Application.ActiveExplorer.CurrentFolder
For Each xAccount In Outlook.Application.Session.Accounts
    Set xDraftFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
    xItemCount = xItemCount + xDraftFld.Items.Count
    If xDraftFld.EntryID = xCurFld.EntryID Then
        Set xTmpFld = xCurFld.Parent
    End If
Next xAccount
Set xDraftFld = Nothing
If xItemCount > 0 Then
   xPromptStr = "Are you sure to send out all the drafts?"
    xYesOrNo = MsgBox(xPromptStr, vbQuestion + vbYesNo, "Kutools for Outlook")
    If xYesOrNo = vbYes Then
        If Not xTmpFld Is Nothing Then
            Set Application.ActiveExplorer.CurrentFolder = xTmpFld
        End If
        VBA.DoEvents
        For Each xAccount In Outlook.Application.Session.Accounts
            Set xDraftFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
            Set xDraftsItems = xDraftFld.Items
            For i = xDraftsItems.Count To 1 Step -1
                If xDraftsItems.Item(i).Recipients.Count <> 0 Then
                    xDraftsItems.Item(i).sEnd
                    xCount = xCount + 1
                End If
            Next
        Next xAccount
        VBA.DoEvents
        Set Application.ActiveExplorer.CurrentFolder = xCurFld
        MsgBox "Successfully sent " & xCount & " messages", vbInformation, "Kutools for Outlook"
    End If
Else
    MsgBox "No Drafts!", vbInformation + vbOKOnly, "Kutools for Outlook"
End If
End Sub

3. Nato shranite kodo in pritisnite F5 tipko za zagon te kode, se prikaže pozivno polje, ki vas opozori, če želite poslati vse osnutke, kliknite Da, glej posnetek zaslona:

4. Odprlo se bo pogovorno okno, ki vas bo opozorilo, koliko osnutkov e-poštnih sporočil je bilo poslanih, glejte posnetek zaslona:

5. In nato kliknite OK gumb, vsa e-poštna sporočila v Osnutki mapa bo poslana naenkrat, glej posnetek zaslona:

Opombe:

1. Zgornja koda bo poslala vsa osnutka e-poštnih sporočil iz vseh računov v Outlooku.

2. Če želite poslati nekatera posebna e-poštna sporočila iz mape Osnutki, uporabite naslednjo kodo VBA:

Koda VBA: Pošlji izbrano e-pošto iz mape Osnutki:

Sub SendSelectedDraftEmails()
Dim xSelection As Selection
Dim xPromptStr As String
Dim xYesOrNo As Integer
Dim i As Long
Dim xAccount As Account
Dim xCurFld As Folder
Dim xDraftsFld As Folder
Dim xTmpFld As Folder
Dim xArr() As String
Dim xCount As Integer
Dim xMail As MailItem
On Error Resume Next
xCount = 0
Set xTmpFld = Nothing
Set xCurFld = Application.ActiveExplorer.CurrentFolder
For Each xAccount In Outlook.Application.Session.Accounts
    Set xDraftsFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
    If xDraftsFld.EntryID = xCurFld.EntryID Then
        Set xTmpFld = xCurFld.Parent
    End If
Next xAccount
If xTmpFld Is Nothing Then
    MsgBox "The current folder is not a draft folder", vbInformation, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection.Count > 0 Then
    xPromptStr = "Are you sure to send out the selected " & xSelection.Count & " draft item(s)?"
    xYesOrNo = MsgBox(xPromptStr, vbQuestion + vbYesNo, "Kutools for Outlook")
    If xYesOrNo = vbYes Then
        ReDim xArr(xSelection.Count - 1)
        For i = 1 To xSelection.Count
            xArr(i - 1) = xSelection.Item(i).EntryID
        Next
        Set Application.ActiveExplorer.CurrentFolder = xTmpFld
        VBA.DoEvents
        For i = 0 To UBound(xArr)
            Set xMail = Application.Session.GetItemFromID(xArr(i))
            If xMail.Recipients.Count <> 0 Then
                xMail.sEnd
                xCount = xCount + 1
            End If
        Next
        VBA.DoEvents
        Set Application.ActiveExplorer.CurrentFolder = xCurFld
        MsgBox "Successfully sent " & xCount & " messages", vbInformation, "Kutools for Outlook"
    End If
Else
    MsgBox "No items selected!", vbInformation, "Kutools for Outlook"
End If
End Sub

Sorodni članki:

Kako poslati e-pošto več prejemnikom posamezno v programu Outlook?

Kako poslati množična e-poštna sporočila na seznam iz Excela prek Outlooka?

Kako poslati koledar posameznim prejemnikom v Outlooku?

Kako poslati e-pošto več prejemnikom, ne da bi oni vedeli v programu Outlook?