Excel CHOOSE funkcija

Opis

Sintaksa in argumenti

Uporaba in primeri

• Ex1 - Osnovna uporaba: uporaba CHOOSE samo funkcija za izbiro vrednosti iz argumenta seznama
• Ex2 - Vrnite različne rezultate glede na več pogojev
• Ex3 - Vrnite različne izračunane rezultate glede na pogoje
• Ex4 - Izberite naključno s seznama
• Ex5 - Kombiniraj CHOOSE in VLOOKUP funkcije za vrnitev vrednosti v levem stolpcu
• Ex6 - Vrnitev delovnega dne ali meseca glede na dani datum
• Ex7 - Vrnitev na datum naslednjega delovnega dne / vikenda glede na današnji dan

---

Opis

O CHOOSE funkcija vrne vrednost s argumenta seznama vrednosti na podlagi podane številke indeksa. Na primer CHOOSE(3,”Apple”,”Peach”,”Orange”) vrne Orange, indeksna številka je 3, Orange pa je tretja vrednost za indeksno številko v funkciji.

sintaksa in argumenti

Sintaksa formule

CHOOSE(index_num, value1, [value2], …)

Argumenti

Index_num: Obvezno. Številska vrednost med 1-254, ki posredno izbere vrednost argumenta. če je številka indeksa zunaj lestvice med 1-254, CHOOSE vrne #VALUE! vrednost napake. Če je index_num decimalna vrednost, bo pred uporabo formule zaokroženo na celo število. Value1: Obvezno. Prva vrednost v formuli, ki jo lahko izberete. Value2: Neobvezno. Druga in do 254. vrednosti, med katerimi lahko izbirate.

Value1, value2… Lahko so številke, besedila, formule, sklici na celice ali določeno ime.

Vrnjena vrednost

O CHOOSE funkcija vrne vrednost s seznama na podlagi danega položaja.

Uporaba in primeri

V tem delu navajam nekaj preprostih, a reprezentativnih primerov, ki pojasnjujejo uporabo CHOOSE Funkcija.

Ex1 - Osnovna uporaba: uporaba CHOOSE samo funkcija za izbiro vrednosti iz argumenta seznama

Formula 1:

=CHOOSE(3,"a","b","c","d")

Vrnitev: c, kar je tretji argument za indeksnim številom 3 v CHOOSE Funkcija.

Opomba: z dvojnimi narekovaji, ki obkrožajo vrednost, če gre za besedilo.

Formula 2:

=CHOOSE(2,A1,A2,A3,A4)

Vrnitev: Kate, vrednost A2. Ker je index_num 2, in A2 je druga vrednost v CHOOSE Funkcija.

Formula 3:

=CHOOSE(4,8,9,7,6)

Vrnitev: 6, argument 4. seznama v funkciji.

---

Ex2 - Vrnite različne rezultate glede na več pogojev

Recimo, da imate seznam odstopanj za vsak izdelek, ki bi ga morali označiti glede na pogoje, kot je prikazano spodaj.

Običajno lahko za ravnanje uporabite funkcijo IF, tukaj pa predstavljam, kako uporabljati CHOOSE funkcijo za enostavno rešitev problema

Formula:

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

Pojasnite:

(B7>0)+(B7>1)+(B7>5): index_num, B7 je 2, kar je večje od 0 in 1, vendar manj kot 5, zato dobimo vmesni rezultat:

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

Kot vemo, True = 1, False = 0, zato lahko formulo vidimo kot:

=CHOOSE(1+1+0,"Top","Middle","Bottom")

POTEM

=CHOOSE(2,"Top","Middle","Bottom")

Rezultat: Srednja

---

Ex3 - Vrnite različne izračunane rezultate glede na pogoje

Recimo, da morate za vsak izdelek izračunati rabate glede na znesek in ceno, kot je prikazano spodaj:

Formula:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

Pojasnite:

(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8 je 102, kar je večje od 100, vendar manj kot 201, zato v tem delu vrne rezultat, prikazan kot:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

POTEM

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: vrednosti, med katerimi lahko izbirate, rabat je enak ceni * znesek * odstotek popusta, saj je tu index_num 2, izbere B8 * C8 * 0.2

Vrne: 102 * 2 * 0.2 = 40.8

---

Ex4 - Izberite naključno s seznama

V Excelu boste včasih morda morali naključno izbrati vrednost s danega seznama, CHOOSE funkcija lahko reši to nalogo.

Naključno izberite eno vrednost s seznama:

Formula:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

Pojasnite:

RANDBETWEEN(1,5): index_num, naključno pridobite število med 1 in 5

$D$2,$D$3,$D$4,$D$5,$D$6: seznam vrednosti, med katerimi lahko izbirate

---

Ex5 - Kombiniraj CHOOSE in VLOOKUP funkcije za vrnitev vrednosti v levem stolpcu

Na splošno uporabljamo funkcijo VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) za vrnitev vrednosti na podlagi dane vrednosti iz obsega tabele. Toda z VLOOKUP vrne vrednost napake, medtem ko je stolpec za vrnitev na levi strani stolpca za iskanje, kot je prikazano spodaj:

V tem primeru lahko kombinirate CHOOSE funkcija s funkcijo VLOOKUP za rešitev težave.

Formula:

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

Pojasnite:

CHOOSE({1,2},B1:B7,A1:A7): kot argument table_range v funkciji VLOOKUP. {1,2} pomeni prikazati 1 ali 2 kot argument index_num, ki temelji na argumentu col_num v funkciji VLOOKUP. Tu je col_num v funkciji VLOOKUP 2, zato je CHOOSE prikaz funkcije kot CHOOSE(2, B1:B7,A1:A7), pomeni izbrati vrednost med A1: A7.

---

Ex6 - Vrnitev delovnega dne ali meseca glede na dani datum

Z CHOOSE lahko vrnete tudi relativni dan v tednu in mesec glede na določen datum.

Formula 1: vrni delovni dan po datumu

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

Pojasnite:

WEEKDAY(): argument index_num, da dobimo številko delovnega dne določenega datuma, na primer WEEKDAY (A5) vrne 6, potem je argument index_num 6.

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": argumenti seznama vrednosti, začnite z »nedelja«, ker številka delovnega dne »1« označuje »nedeljo«.

Formula 2: vrni mesec po datumu

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Pojasnite:

MONTH(): Argument index_num, ki dobi številko meseca od določenega datuma, na primer MONTH (A5) vrne 3.

---

Ex7 - Vrnitev na datum naslednjega delovnega dne / vikenda glede na današnji dan

Pri vsakodnevnem delu boste morda želeli izračunati naslednji delovni dan ali konec tedna na podlagi današnjega dne. Tukaj CHOOSE funkcija vam lahko tudi naredi uslugo.

Na primer, danes je 12. 20. 2018, četrtek, zdaj morate dobiti naslednji delovni dan in konec tedna.

Formula 1: dobite datum danes

=TODAY()

Rezultat: 12

Formula 2: dobite številko danes v tednu

=WEEKDAY(TODAY())

Rezultat: 5 (medtem ko je danes 12)

Seznam številk delovnega dne, kot je prikazano na sliki spodaj:

Formula 3: dobili naslednji delovni dan

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Pojasnite:

Today(): vrne trenutni datum

WEEKDAY(TODAY()): argument_inum v CHOOSE funkcija, dobite danes številko delovnega dne, na primer nedelja je 1, ponedeljek je 2…

1,1,1,1,1,3,2: argument seznama vrednosti v CHOOSE funkcijo. Če na primer delovni dan (danes ()) vrne 1 (nedelja), izbere 1 s seznama vrednosti, potem se celotna formula spremeni v = Danes () + 1, kar pomeni, da dodate 1 dan za vrnitev naslednji ponedeljek. Če se delovni dan (danes ()) vrne 6 (petek), izbere 3 s seznama vrednosti, ker je petek 3 dni daleč od naslednjega ponedeljka.

Rezultat (medtem ko je danes 12):

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

= 12. 20. 2018 + 1

= 12. 21. 2018

Formula 4: dobite naslednji vikend dan

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

Pojasnite:

6,5,4,3,2,1,1: argument seznama vrednosti v CHOOSE funkcijo. Če na primer delovni dan (danes ()) vrne 1 (nedelja), s seznama vrednosti izbere 6, potem se celotna formula spremeni v = Danes () + 6, kar pomeni, da dodate 6 dni in se vrnete prihodnjo soboto.

Rezultat:

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

= 12. 20. 2018 + 2

= 12. 22. 2018

---

Vzorčna datoteka