Kako preprečiti, da Outlook spominja prezgodaj ali prepozno?

Na primer, vsak dan delate od 9:00 do 6:00, zdaj pa se dogovorite za sestanek ob 10:00 in v Outlooku dodate opomnik za 2 uri. To pomeni, da bo opomnik deloval ob 8:00 zjutraj pred začetkom vašega dela. Po drugi strani pa se lahko opomnik v posebnih primerih oglasi polnoči. To je precej neprijetno in nekateri uporabniki Outlooka bodo morda želeli preprečiti, da bi Outlook spominjal prezgodaj ali prepozno. Tukaj bom predstavil makro VBA, ki ga boste rešili v Outlooku.

Če želite preprečiti, da bi Outlook spominjal prezgodaj ali prepozno, lahko storite naslednje:

Korak 1: Pritisnite tipko druga + F11 medtem odprete okno Microsoft Visual Basic for Applications.

2. korak: Razširite Predmeti Microsoft Outlook v levo podokno in v mapo prilepite naslednji makro VBA Ta OutlookSession.

VBA: Preprečite prezgodaj ali prepozno opominjanje v programu Outlook

Public WithEvents g_CalendarItems As Outlook.Items
Public Sub Application_Startup()
Set g_CalendarItems = Outlook.Session.GetDefaultFolder(olFolderCalendar).Items
End Sub
Private Sub g_CalendarItems_ItemAdd(ByVal Item As Object)
CheckReminder Item
End Sub
Private Sub g_CalendarItems_ItemChange(ByVal Item As Object)
CheckReminder Item
End Sub
Sub CheckReminder(ByVal Item As Object)
On Error GoTo ProcError
Dim strProcName As String
strProcName = "CheckReminder"
reminderMaxHour = 20
reminderMinHour = 9
Dim aAptItem As Outlook.AppointmentItem
Set aAptItem = Item
If aAptItem.ReminderSet Then
Dim reminderDate As Date
reminderDate = aAptItem.Start - aAptItem.ReminderMinutesBeforeStart / (24 * 60)
reminderHour = (reminderDate - Int(reminderDate)) * 24
tolerance = 0.01 ' avoid floating point small diffs (little bit less than a min)
If reminderHour < reminderMinHour - tolerance Or reminderHour > reminderMaxHour + tolerance Then
' best guess, first try to advance to next minHour
reminderDateSuggestion = reminderDate + (reminderMinHour - reminderHour) / 24
' verify if first guess is valid
If reminderHour < reminderMinHour - tolerance And reminderDateSuggestion <= aAptItem.Start Then
' OK, first guess is valid, keep it
ElseIf reminderHour > reminderMaxHour Then
' go back to max hour (same day)
reminderDateSuggestion = reminderDate - (reminderHour - reminderMaxHour) / 24
Else
' go back to max hour (previous day)
reminderDateSuggestion = reminderDate - (reminderHour + 24 - reminderMaxHour) / 24
End If
rep = MsgBox("The Reminder time is out of specified working period. Would you like to change the Reminder time?" , vbQuestion + vbYesNoCancel)
If rep = vbCancel Then
aAptItem.Display
ElseIf rep = vbYes Then
aAptItem.ReminderMinutesBeforeStart = (aAptItem.Start - reminderDateSuggestion) * 24 * 60
aAptItem.Save
End If
End If
End If
ProcExit:
Exit Sub
ProcError:
MsgBox "Unanticipated error " & Err.Number & " " & Err.Description & vbCrLf & "In procedure: " & strProcName
End Sub

Opombe: Svoje delovno obdobje lahko določite s spreminjanjem naslednjih parametrov v zgornji kodi VBA:
opomnikMaxHour = 20
opomnikMinHour = 9

3. korak: shranite ta VBA in znova zaženite Microsoft Outlook.

Od zdaj naprej se bo pri ustvarjanju sestanka s časom opomnika, ki določa delovno obdobje, pojavilo pogovorno okno, ki vas bo opozorilo po kliku na Shrani in zapri gumb.

Če je čas opomnika zgodnejši od določenega opomnikaMinHour, kliknite Da v pogovornem oknu bo spremenil čas opomnika in sprožil opomnik ob določenem opomniku MinHour.

Če je čas opomnika poznejši od določenega opomnikaMaxHour, kliknite Da v pogovornem oknu bo spremenil čas opomnika in vas opozoril ob določenem opomnikuMaxHour.

Opomba: Ta koda VBA dobro deluje z Outlookom 2013, ne deluje pa z Outlookoma 2010 in 2007.